modules/plugins/utility/oil-nvim/config.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{
  config,
  lib,
  ...
}: let
  inherit (lib.attrsets) optionalAttrs recursiveUpdate;
  inherit (lib.lists) optionals;
  inherit (lib.modules) mkIf;
  inherit (lib.nvim.lua) toLuaObject;
  inherit (lib.nvim.dag) entryAfter entryAnywhere;

  cfg = config.vim.utility.oil-nvim;
in {
  config = mkIf cfg.enable {
    vim = {
      startPlugins = ["oil-nvim"] ++ (optionals cfg.gitStatus.enable ["oil-git-status.nvim"]);

      pluginRC.oil-nvim = let
        gitStatusDefaultOpts = {
          # https://github.com/refractalize/oil-git-status.nvim?tab=readme-ov-file#configuration
          win_options = {
            signcolumn = "yes:2";
          };
        };

        setupOpts =
          recursiveUpdate
          (optionalAttrs cfg.gitStatus.enable gitStatusDefaultOpts)
          cfg.setupOpts;
      in
        entryAnywhere ''
          require("oil").setup(${toLuaObject setupOpts});
        '';

      pluginRC.oil-git-status-nvim = mkIf cfg.gitStatus.enable (entryAfter ["oil-nvim"] ''
        require("oil-git-status").setup(${toLuaObject cfg.gitStatus.setupOpts})
      '');
    };
  };
}