modules/plugins/lsp/presets/vscode-json-language-server.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

{
  config,
  lib,
  pkgs,
  ...
}: let
  inherit (lib.modules) mkIf;
  inherit (lib.nvim.types) mkLspPresetEnableOption;
  inherit (lib.meta) getExe';
  inherit (lib.generators) mkLuaInline;

  cfg = config.vim.lsp.presets.vscode-json-language-server;
in {
  options.vim.lsp.presets.vscode-json-language-server = {
    enable = mkLspPresetEnableOption {
      option = "vscode-json-language-server";
      display = "VSCode JSON";
    };
  };

  config = mkIf cfg.enable {
    vim.lsp.servers.vscode-json-language-server = {
      enable = true;
      cmd = [(getExe' pkgs.vscode-langservers-extracted "vscode-json-language-server") "--stdio"];
      root_markers = [".git"];
      init_options = {provideFormatter = true;};
      get_language_id = mkLuaInline ''
        function(_, ft)
          --[[
            The LSP only supports `json` and `jsonc`.
            The fallback for any unknown file types is `json`.
            Mapping `json5` to `jsonc` generates more accurate results,
            because `jsonc` is a subset of `json5`.
          ]]--
          if ft == "json5" then
            return "jsonc"
          end
          return ft
        end
      '';
    };
  };
}