blob: ab4726269b314e8f5b7cc0340335aea9f42e4157 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
|
{
config,
pkgs,
lib,
...
}: let
inherit (builtins) elem;
inherit (lib.options) mkEnableOption mkOption literalExpression;
inherit (lib) genAttrs;
inherit (lib.modules) mkIf mkMerge;
inherit (lib.types) enum listOf;
inherit (lib.nvim.types) mkGrammarOption;
cfg = config.vim.languages.sql;
defaultServers = ["sqls"];
servers = ["sqls"];
defaultFormat = ["sqlfluff"];
formats = ["sqlfluff" "sqruff" "injected"];
defaultDiagnosticsProvider = ["sqlfluff"];
diagnosticsProviders = ["sqlfluff" "sqruff"];
in {
options.vim.languages.sql = {
enable = mkEnableOption "SQL language support";
treesitter = {
enable =
mkEnableOption "SQL treesitter"
// {
default = config.vim.languages.enableTreesitter;
defaultText = literalExpression "config.vim.languages.enableTreesitter";
};
package = mkGrammarOption pkgs "sql";
};
lsp = {
enable =
mkEnableOption "SQL LSP support"
// {
default = config.vim.lsp.enable;
defaultText = literalExpression "config.vim.lsp.enable";
};
servers = mkOption {
type = listOf (enum servers);
default = defaultServers;
description = "SQL LSP server to use";
};
};
format = {
enable =
mkEnableOption "SQL formatting"
// {
default = config.vim.languages.enableFormat;
defaultText = literalExpression "config.vim.languages.enableFormat";
};
type = mkOption {
type = listOf (enum formats);
default = defaultFormat;
description = "SQL formatter to use";
};
};
extraDiagnostics = {
enable =
mkEnableOption "extra SQL diagnostics via nvim-lint"
// {
default = config.vim.languages.enableExtraDiagnostics;
defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
};
types = mkOption {
type = listOf (enum diagnosticsProviders);
default = defaultDiagnosticsProvider;
description = "extra SQL diagnostics providers";
};
};
extensions = {
sqls-nvim.enable = mkEnableOption "Extended SQL LSP support for SQLS";
};
};
config = mkIf cfg.enable (mkMerge [
(mkIf cfg.treesitter.enable {
vim.treesitter = {
enable = true;
grammars = [cfg.treesitter.package];
queries = [
# Sets some common highlight groups, ensuring that SQL looks correct in more injections
{
type = "highlights";
filetypes = ["sql"];
loadtype = "extends";
query = ''
(identifier) @variable
(parameter) @attribute
(#eq? @attribute "?")
'';
}
# Special comments for some SQL tools
{
type = "highlights";
filetypes = ["sql"];
loadtype = "extends";
query = ''
((comment) @attribute
(#match? @attribute "^--(bun:split| \\+goose)"))
'';
}
];
};
})
(mkIf cfg.lsp.enable {
vim = {
lsp = {
presets = genAttrs cfg.lsp.servers (_: {enable = true;});
servers = genAttrs cfg.lsp.servers (_: {
filetypes = ["sql" "mysql" "msql" "plsql"];
});
};
};
})
(mkIf cfg.format.enable {
vim.formatter.conform-nvim = {
enable = true;
presets = genAttrs cfg.format.type (_: {enable = true;});
setupOpts.formatters_by_ft.sql = cfg.format.type;
};
})
(mkIf cfg.extraDiagnostics.enable {
vim.diagnostics = {
presets = genAttrs cfg.extraDiagnostics.types (_: {
enable = true;
});
nvim-lint = {
enable = true;
linters_by_ft.sql = cfg.extraDiagnostics.types;
};
};
})
(mkIf cfg.extensions.sqls-nvim.enable {
assertions = [
{
assertion = cfg.lsp.enable && elem "sqls" cfg.lsp.servers;
message = ''
`vim.languages.sql.extensions.sqls-nvim.enable` requires `vim.languages.sql.lsp.enable` to be enabled and "sqls" to be included in `vim.languages.sql.lsp.servers`.
'';
}
];
vim.startPlugins = ["sqls-nvim"];
})
]);
}
|
