blob: 5e22f98ede05103d7262c2d10eb0e5f90386e987 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
|
{
config,
pkgs,
lib,
...
}: let
inherit (builtins) attrNames;
inherit (lib.options) mkEnableOption mkOption literalExpression;
inherit (lib.lists) flatten;
inherit (lib) genAttrs;
inherit (lib.modules) mkIf mkMerge;
inherit (lib.types) enum package listOf;
inherit (lib.generators) mkLuaInline;
cfg = config.vim.languages.python;
defaultServers = ["basedpyright"];
servers = ["pyrefly" "pyright" "basedpyright" "python-lsp-server" "ruff" "ty" "zuban"];
defaultFormat = ["black"];
formats = ["black" "isort" "ruff" "ruff-fix" "injected"];
defaultDebugger = ["debugpy"];
dapConfigurations = {
debugpy = [
{
type = "debugpy";
request = "launch";
name = "Launch file";
program = "\${file}";
pythonPath = mkLuaInline ''
function()
-- debugpy supports launching an application with a different interpreter then the one used to launch debugpy itself.
-- The code below looks for a `venv` or `.venv` folder in the current directly and uses the python within.
-- You could adapt this - to for example use the `VIRTUAL_ENV` environment variable.
local cwd = vim.fn.getcwd()
if vim.fn.executable(cwd .. "/venv/bin/python") == 1 then
return cwd .. "/venv/bin/python"
elseif vim.fn.executable(cwd .. "/.venv/bin/python") == 1 then
return cwd .. "/.venv/bin/python"
elseif vim.fn.executable("python") == 1 then
return vim.fn.exepath("python")
else -- this uses the same python package as the debugger
return nil
end
end
'';
}
];
};
defaultDiagnosticsProvider = ["mypy"];
diagnosticsProviders = ["mypy"];
in {
options.vim.languages.python = {
enable = mkEnableOption "Python language support";
treesitter = {
enable =
mkEnableOption "Python treesitter"
// {
default = config.vim.languages.enableTreesitter;
defaultText = literalExpression "config.vim.languages.enableTreesitter";
};
package = mkOption {
description = "Python treesitter grammar to use";
type = package;
default = pkgs.vimPlugins.nvim-treesitter.grammarPlugins.python;
};
};
lsp = {
enable =
mkEnableOption "Python LSP support"
// {
default = config.vim.lsp.enable;
defaultText = literalExpression "config.vim.lsp.enable";
};
servers = mkOption {
type = listOf (enum servers);
default = defaultServers;
description = "Python LSP server to use";
};
};
format = {
enable =
mkEnableOption "Python formatting"
// {
default = config.vim.languages.enableFormat;
defaultText = literalExpression "config.vim.languages.enableFormat";
};
type = mkOption {
type = listOf (enum formats);
default = defaultFormat;
description = "Python formatters to use";
};
};
# TODO this implementation is very bare bones, I don't know enough python to implement everything
dap = {
enable =
mkEnableOption "Python Debug Adapter"
// {
default = config.vim.languages.enableDAP;
defaultText = literalExpression "config.vim.languages.enableDAP";
};
debugger = mkOption {
type = listOf (enum (attrNames dapConfigurations));
default = defaultDebugger;
description = "Python debugger to use";
};
};
extraDiagnostics = {
enable =
mkEnableOption "extra Python diagnostics via nvim-lint"
// {
default = config.vim.languages.enableExtraDiagnostics;
defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
};
types = mkOption {
type = listOf (enum diagnosticsProviders);
default = defaultDiagnosticsProvider;
description = "extra Python diagnostics providers";
};
};
};
config = mkIf cfg.enable (mkMerge [
(mkIf cfg.treesitter.enable {
vim.treesitter.enable = true;
vim.treesitter.grammars = [cfg.treesitter.package];
})
(mkIf cfg.lsp.enable {
vim.lsp = {
presets = genAttrs cfg.lsp.servers (_: {enable = true;});
servers = genAttrs cfg.lsp.servers (_: {
filetypes = ["python"];
root_markers = [
"Pipfile"
"pyproject.toml"
"requirements.txt"
"setup.cfg"
"setup.py"
];
});
};
})
(mkIf cfg.format.enable {
vim.formatter.conform-nvim = {
enable = true;
presets = genAttrs cfg.format.type (_: {enable = true;});
setupOpts.formatters_by_ft.python = cfg.format.type;
};
})
(mkIf cfg.dap.enable {
vim.debugger.nvim-dap = {
enable = true;
presets = genAttrs cfg.dap.debugger (_: {enable = true;});
configurations.python = flatten (map (name: dapConfigurations.${name}) cfg.dap.debugger);
};
})
(mkIf cfg.extraDiagnostics.enable {
vim.diagnostics = {
presets = genAttrs cfg.extraDiagnostics.types (_: {enable = true;});
nvim-lint = {
enable = true;
linters_by_ft.python = cfg.extraDiagnostics.types;
};
};
})
]);
}
|
