blob: ef18602558ca0dbdfa2b97a1ffef0003e1a0e761 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
{
config,
pkgs,
lib,
...
}: let
inherit (lib.options) mkOption mkEnableOption literalExpression;
inherit (lib.modules) mkIf mkMerge;
inherit (lib.types) enum listOf;
inherit (lib) genAttrs elem;
inherit (lib.nvim.types) mkGrammarOption;
cfg = config.vim.languages.pug;
defaultServers = ["emmet-ls"];
servers = ["emmet-ls"];
defaultFormat = ["prettier"];
formats = ["prettier" "injected"];
in {
options.vim.languages.pug = {
enable = mkEnableOption "Pug language support";
treesitter = {
enable =
mkEnableOption "Pug treesitter"
// {
default = config.vim.languages.enableTreesitter;
defaultText = literalExpression "config.vim.languages.enableTreesitter";
};
package = mkGrammarOption pkgs "pug";
};
lsp = {
enable =
mkEnableOption "Pug LSP support"
// {
default = config.vim.lsp.enable;
defaultText = literalExpression "config.vim.lsp.enable";
};
servers = mkOption {
type = listOf (enum servers);
default = defaultServers;
description = "Pug LSP server to use";
};
};
format = {
enable =
mkEnableOption "Pug formatting"
// {
default = config.vim.languages.enableFormat;
defaultText = literalExpression "config.vim.languages.enableFormat";
};
type = mkOption {
type = listOf (enum formats);
default = defaultFormat;
description = "Pug formatter to use";
};
};
};
config = mkIf cfg.enable (mkMerge [
(mkIf cfg.treesitter.enable {
vim.treesitter = {
enable = true;
grammars = [cfg.treesitter.package];
};
})
(mkIf cfg.lsp.enable {
vim.lsp = {
presets = genAttrs cfg.lsp.servers (_: {enable = true;});
servers = genAttrs cfg.lsp.servers (_: {filetypes = ["pug"];});
};
})
(mkIf cfg.format.enable {
vim.formatter.conform-nvim = {
enable = true;
presets = genAttrs cfg.format.type (_: {enable = true;});
setupOpts.formatters_by_ft.pug = cfg.format.type;
};
})
(mkIf (cfg.format.enable && (elem "prettier" cfg.format.type)) {
vim.formatter.conform-nvim.presets.prettier.plugins = ["pug"];
})
]);
}
|
