blob: 41cdced491f7370d010358e080a2b82da92fe5fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
|
{
config,
pkgs,
lib,
...
}: let
inherit (builtins) attrNames;
inherit (lib.options) mkEnableOption mkOption literalExpression;
inherit (lib) genAttrs;
inherit (lib.modules) mkIf mkMerge;
inherit (lib.lists) flatten;
inherit (lib.types) enum listOf;
inherit (lib.nvim.types) mkGrammarOption;
cfg = config.vim.languages.php;
defaultServers = ["phpactor"];
servers = ["phpactor" "phan" "intelephense" "phpantom"];
defaultFormat = ["php-cs-fixer"];
formats = ["php-cs-fixer" "mago" "mago-fix" "injected"];
defaultDiagnosticsProvider = ["phpstan"];
diagnosticsProviders = ["phpstan" "mago_lint" "mago_analyze"];
defaultDebugger = ["xdebug"];
dapConfigurations = {
xdebug = let
port = 9003;
in [
{
type = "xdebug";
request = "launch";
name = "Listen for XDebug at port ${toString port}";
inherit port;
}
];
};
in {
options.vim.languages.php = {
enable = mkEnableOption "PHP language support";
treesitter = {
enable =
mkEnableOption "PHP treesitter"
// {
default = config.vim.languages.enableTreesitter;
defaultText = literalExpression "config.vim.languages.enableTreesitter";
};
package = mkGrammarOption pkgs "php";
};
lsp = {
enable =
mkEnableOption "PHP LSP support"
// {
default = config.vim.lsp.enable;
defaultText = literalExpression "config.vim.lsp.enable";
};
servers = mkOption {
type = listOf (enum servers);
default = defaultServers;
description = "PHP LSP server to use";
};
};
format = {
enable =
mkEnableOption "PHP formatting"
// {
default = config.vim.languages.enableFormat;
defaultText = literalExpression "config.vim.languages.enableFormat";
};
type = mkOption {
description = "PHP formatter to use";
type = listOf (enum formats);
default = defaultFormat;
};
};
dap = {
enable =
mkEnableOption "Enable PHP Debug Adapter"
// {
default = config.vim.languages.enableDAP;
defaultText = literalExpression "config.vim.languages.enableDAP";
};
debugger = mkOption {
type = listOf (enum (attrNames dapConfigurations));
default = defaultDebugger;
description = "PHP debugger to use";
};
};
extraDiagnostics = {
enable =
mkEnableOption "extra PHP diagnostics via nvim-lint"
// {
default = config.vim.languages.enableExtraDiagnostics;
defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
};
types = mkOption {
type = listOf (enum diagnosticsProviders);
default = defaultDiagnosticsProvider;
description = "extra PHP diagnostics providers";
};
};
};
config = mkIf cfg.enable (mkMerge [
(mkIf cfg.treesitter.enable {
vim.treesitter.enable = true;
vim.treesitter.grammars = [cfg.treesitter.package];
})
(mkIf cfg.lsp.enable {
vim.lsp = {
presets = genAttrs cfg.lsp.servers (_: {enable = true;});
servers = genAttrs cfg.lsp.servers (_: {
filetypes = ["php"];
root_markers = ["composer.json"];
});
};
})
(mkIf cfg.format.enable {
vim.formatter.conform-nvim = {
enable = true;
presets = genAttrs cfg.format.type (_: {enable = true;});
setupOpts.formatters_by_ft.php = cfg.format.type;
};
})
(mkIf cfg.dap.enable {
vim.debugger.nvim-dap = {
enable = true;
presets = genAttrs cfg.dap.debugger (_: {enable = true;});
configurations.php = flatten (map (name: dapConfigurations.${name}) cfg.dap.debugger);
};
})
(mkIf cfg.extraDiagnostics.enable {
vim.diagnostics = {
presets = genAttrs cfg.extraDiagnostics.types (_: {enable = true;});
nvim-lint = {
enable = true;
linters_by_ft.php = cfg.extraDiagnostics.types;
};
};
})
]);
}
|
