blob: 08f0d7331868c8cef0bf18a166e10b2f87ff8cdf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
{
config,
pkgs,
lib,
...
}: let
inherit (lib) concatStringsSep genAttrs elem;
inherit (lib.options) mkEnableOption mkOption literalExpression;
inherit (lib.modules) mkIf mkMerge;
inherit (lib.types) enum listOf;
inherit (lib.nvim.types) mkGrammarOption;
cfg = config.vim.languages.nix;
defaultServers = ["nil"];
servers = ["nil" "nixd"];
defaultFormat = ["alejandra"];
formats = ["alejandra" "nixfmt" "nixfmt-rs" "injected"];
defaultDiagnosticsProvider = ["statix" "deadnix"];
diagnosticsProviders = ["statix" "deadnix"];
in {
options.vim.languages.nix = {
enable = mkEnableOption "Nix language support";
treesitter = {
enable =
mkEnableOption "Nix treesitter"
// {
default = config.vim.languages.enableTreesitter;
defaultText = literalExpression "config.vim.languages.enableTreesitter";
};
package = mkGrammarOption pkgs "nix";
};
lsp = {
enable =
mkEnableOption "Nix LSP support"
// {
default = config.vim.lsp.enable;
defaultText = literalExpression "config.vim.lsp.enable";
};
servers = mkOption {
type = listOf (enum servers);
default = defaultServers;
description = "Nix LSP server to use";
};
};
format = {
enable =
mkEnableOption "Nix formatting"
// {
default = config.vim.languages.enableFormat;
defaultText = literalExpression "config.vim.languages.enableFormat";
};
type = mkOption {
description = "Nix formatter to use";
type = listOf (enum formats);
default = defaultFormat;
};
};
extraDiagnostics = {
enable =
mkEnableOption "extra Nix diagnostics via nvim-lint"
// {
default = config.vim.languages.enableExtraDiagnostics;
defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
};
types = mkOption {
type = listOf (enum diagnosticsProviders);
default = defaultDiagnosticsProvider;
description = "extra Nix diagnostics providers";
};
};
};
config = mkIf cfg.enable (mkMerge [
{
assertions = [
{
assertion = !(elem "nixpkgs-fmt" cfg.format.type);
message = ''
nixpkgs-fmt has been archived upstream. Please use one of the following available formatters:
${concatStringsSep ", " formats}
'';
}
];
}
(mkIf cfg.treesitter.enable {
vim.treesitter = {
enable = true;
grammars = [cfg.treesitter.package];
queries = [
# query = ''; -> query
{
type = "injections";
filetypes = ["nix"];
loadtype = "extends";
query = ''
(binding
attrpath: (attrpath
(identifier) @_path)
(#eq? @_path "query")
expression: [
(string_expression
((string_fragment) @injection.content
(#set! injection.language "query")
(#set! injection.combined)))
(indented_string_expression
((string_fragment) @injection.content
(#set! injection.language "query")
(#set! injection.combined)))
(apply_expression
argument: [
(string_expression
((string_fragment) @injection.content
(#set! injection.language "query")
(#set! injection.combined)))
(indented_string_expression
((string_fragment) @injection.content
(#set! injection.language "query")
(#set! injection.combined)))
])
])
'';
}
# mkLuaInline, entryAnywhere, entryBefore, entryAfter -> lua
{
type = "injections";
filetypes = ["nix"];
loadtype = "extends";
query = ''
((apply_expression
function: (variable_expression
name: (identifier) @_func
(#any-of? @_func "mkLuaInline" "entryAnywhere"))
argument: (indented_string_expression
(string_fragment) @injection.content))
(#set! injection.language "lua")
(#set! injection.combined))
((apply_expression
function: (apply_expression
function: (variable_expression
name: (identifier) @_func
(#any-of? @_func "entryBefore" "entryAfter"))
argument: (_))
argument: (indented_string_expression
(string_fragment) @injection.content))
(#set! injection.language "lua")
(#set! injection.combined))
'';
}
];
};
})
(mkIf cfg.lsp.enable {
vim.lsp = {
presets = genAttrs cfg.lsp.servers (_: {enable = true;});
servers = genAttrs cfg.lsp.servers (_: {
filetypes = ["nix"];
root_markers = ["flake.nix"];
});
};
})
(mkIf cfg.format.enable {
vim.formatter.conform-nvim = {
enable = true;
presets = genAttrs cfg.format.type (_: {enable = true;});
setupOpts.formatters_by_ft.nix = cfg.format.type;
};
})
(mkIf cfg.extraDiagnostics.enable {
vim.diagnostics = {
presets = genAttrs cfg.extraDiagnostics.types (_: {enable = true;});
nvim-lint = {
enable = true;
linters_by_ft.nix = cfg.extraDiagnostics.types;
};
};
})
]);
}
|
