blob: 4c56c17a6e6972c772e09d94c6af952b70f79a4a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
{
config,
pkgs,
lib,
...
}: let
inherit (lib.options) mkOption mkEnableOption literalExpression;
inherit (lib.modules) mkIf mkMerge;
inherit (lib.types) enum listOf;
inherit (lib.attrsets) genAttrs;
inherit (lib.nvim.types) mkGrammarOption;
cfg = config.vim.languages.json;
defaultServers = ["vscode-json-language-server"];
servers = ["vscode-json-language-server"];
defaultFormat = ["jsonfmt"];
formats = ["jsonfmt" "prettier" "biome" "deno" "injected"];
in {
options.vim.languages.json = {
enable = mkEnableOption "JSON language support";
treesitter = {
enable =
mkEnableOption "JSON treesitter"
// {
default = config.vim.languages.enableTreesitter;
defaultText = literalExpression "config.vim.languages.enableTreesitter";
};
package = mkGrammarOption pkgs "json";
};
lsp = {
enable =
mkEnableOption "JSON LSP support"
// {
default = config.vim.lsp.enable;
defaultText = literalExpression "config.vim.lsp.enable";
};
servers = mkOption {
type = listOf (enum servers);
default = defaultServers;
description = "JSON LSP server to use";
};
};
format = {
enable =
mkEnableOption "JSON formatting"
// {
default = config.vim.languages.enableFormat;
defaultText = literalExpression "config.vim.languages.enableFormat";
};
type = mkOption {
description = "JSON formatter to use";
type = listOf (enum formats);
default = defaultFormat;
};
};
};
config = mkIf cfg.enable (mkMerge [
(mkIf cfg.treesitter.enable {
vim.treesitter = {
enable = true;
grammars = [cfg.treesitter.package];
};
})
(mkIf cfg.lsp.enable {
vim.lsp = {
presets = genAttrs cfg.lsp.servers (_: {enable = true;});
servers = genAttrs cfg.lsp.servers (_: {
filetypes = ["json" "jsonc"];
});
};
})
(mkIf cfg.format.enable {
vim.formatter.conform-nvim = {
enable = true;
presets = genAttrs cfg.format.type (_: {enable = true;});
setupOpts.formatters_by_ft = {
json = cfg.format.type;
jsonc = cfg.format.type;
};
};
})
]);
}
|
