blob: cba4ad12a364e3465f6d426765851307b1e3a711 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
{ lib, pkgs, ... }:
let
nixpkgsFun = import ../../top-level;
in
lib.recurseIntoAttrs {
platformEquality =
let
configsLocal = [
# crossSystem is implicitly set to localSystem.
{
localSystem = {
system = "x86_64-linux";
};
}
{
localSystem = {
system = "aarch64-linux";
};
crossSystem = null;
}
# Both systems explicitly set to the same string.
{
localSystem = {
system = "x86_64-linux";
};
crossSystem = {
system = "x86_64-linux";
};
}
# Vendor and ABI inferred from system double.
{
localSystem = {
system = "aarch64-linux";
};
crossSystem = {
config = "aarch64-unknown-linux-gnu";
};
}
];
configsCross = [
# GNU is inferred from double, but config explicitly requests musl.
{
localSystem = {
system = "aarch64-linux";
};
crossSystem = {
config = "aarch64-unknown-linux-musl";
};
}
# Cross-compile from AArch64 to x86-64.
{
localSystem = {
system = "aarch64-linux";
};
crossSystem = {
system = "x86_64-unknown-linux-gnu";
};
}
];
pkgsLocal = map nixpkgsFun configsLocal;
pkgsCross = map nixpkgsFun configsCross;
in
assert lib.all (p: p.stdenv.buildPlatform == p.stdenv.hostPlatform) pkgsLocal;
assert lib.all (p: p.stdenv.buildPlatform != p.stdenv.hostPlatform) pkgsCross;
pkgs.emptyFile;
# appendOverlays must preserve splicing so that cross-compilation
# works in NixOS modules (which go through appendOverlays via nixpkgs.nix).
appendOverlaysPreservesSplicing =
let
cross = nixpkgsFun {
localSystem = {
system = "x86_64-linux";
};
crossSystem = {
system = "aarch64-linux";
};
};
appended = cross.appendOverlays [ ];
in
assert cross.makeWrapper ? __spliced;
assert appended.makeWrapper ? __spliced;
pkgs.emptyFile;
replaceStdenv =
let
replacedPkgs = nixpkgsFun {
localSystem = {
inherit (pkgs.stdenv.buildPlatform) system;
};
config.replaceStdenv =
{ pkgs }:
assert !(pkgs.config ? replaceStdenv);
pkgs.stdenv
// {
wasReplaced = true;
};
};
in
assert replacedPkgs.stdenv.wasReplaced;
pkgs.emptyFile;
replaceStdenvIgnoredForCross =
let
crossPkgs = nixpkgsFun {
localSystem = {
system = "x86_64-linux";
};
crossSystem = {
system = "aarch64-linux";
};
config.replaceStdenv = _: throw "replaceStdenv must be ignored when cross compiling";
};
in
assert crossPkgs.stdenv.buildPlatform != crossPkgs.stdenv.hostPlatform;
pkgs.emptyFile;
massRebuildVariantComposition =
let
variants = [
"pkgsChecked"
"pkgsParallel"
"pkgsStrict"
"pkgsStructured"
];
all = lib.getAttrFromPath variants pkgs;
all-reversed = lib.getAttrFromPath (lib.reverseList variants) pkgs;
in
assert pkgs.config.allowVariants -> (all.hello == all-reversed.hello);
pkgs.emptyFile;
}
|
