1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
{
lib,
stdenvNoCC,
libsass,
nodejs,
pnpm_11,
fetchPnpmDeps,
pnpmConfigHook,
fetchFromGitHub,
nixosTests,
vips,
}:
let
pinData = lib.importJSON ./pin.json;
in
stdenvNoCC.mkDerivation (finalAttrs: {
pname = "lemmy-ui";
version = pinData.uiVersion;
src = fetchFromGitHub {
owner = "LemmyNet";
repo = "lemmy-ui";
tag = finalAttrs.version;
fetchSubmodules = true;
hash = pinData.uiHash;
};
nativeBuildInputs = [
nodejs
pnpmConfigHook
pnpm_11
];
buildInputs = [
libsass
vips
];
pnpmDeps = fetchPnpmDeps {
inherit (finalAttrs) pname version src;
pnpm = pnpm_11;
fetcherVersion = 4;
hash = pinData.uiPNPMDepsHash;
};
buildPhase = ''
runHook preBuild
pnpm run prebuild:prod
# Required to pass a custom value for COMMIT_HASH, as the normal
# `pnpm build:prod` tries to derive its value by running `git`.
# This value is only injected into the templated asset URLs for cache invalidation,
# so we don't really need a commit hash here, just a value that changes on every
# update.
pnpm exec webpack --env COMMIT_HASH="${finalAttrs.version}" --mode=production
runHook postBuild
'';
preInstall = ''
mkdir $out
cp -R ./dist $out
cp -R ./node_modules $out
'';
preFixup = ''
find $out -name libvips-cpp.so.42 -print0 | while read -d $'\0' libvips; do
echo replacing libvips at $libvips
rm $libvips
ln -s ${lib.getLib vips}/lib/libvips-cpp.so.42 $libvips
done
'';
passthru = {
updateScript = ./update.py;
tests.lemmy-ui = nixosTests.lemmy;
};
meta = {
description = "Web frontend for a federated link aggregator";
homepage = "https://join-lemmy.org/";
license = lib.licenses.agpl3Only;
maintainers = with lib.maintainers; [
happysalada
billewanick
georgyo
lucasew
];
teams = [ lib.teams.ngi ];
inherit (nodejs.meta) platforms;
};
})
|
