1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
|
{
lib,
stdenv,
fetchurl,
fetchpatch2,
autoreconfHook,
pkg-config,
perl,
zlib,
apr,
aprutil,
pcre2,
libiconv,
lynx,
withLynx ? false,
which,
libxcrypt,
buildPackages,
pkgsCross,
runCommand,
nixosTests,
proxySupport ? true,
sslSupport ? true,
openssl,
http2Support ? true,
nghttp2,
ldapSupport ? true,
openldap,
libxml2Support ? true,
libxml2,
brotliSupport ? true,
brotli,
luaSupport ? false,
lua5,
systemdSupport ? lib.meta.availableOn stdenv.hostPlatform systemdLibs,
systemdLibs,
}:
stdenv.mkDerivation rec {
pname = "apache-httpd";
version = "2.4.68";
src = fetchurl {
url = "mirror://apache/httpd/httpd-${version}.tar.bz2";
hash = "sha256-aMdNTfOMJr7U372487rx61MvOHI1e+zBu6XRNva2PAY=";
};
patches = [
# Fix cross-compilation by using CC_FOR_BUILD for generator program
# https://issues.apache.org/bugzilla/show_bug.cgi?id=51257#c6
(fetchpatch2 {
name = "apache-httpd-cross-compile.patch";
url = "https://gitlab.com/buildroot.org/buildroot/-/raw/5dae8cddeecf16c791f3c138542ec51c4e627d75/package/apache/0001-cross-compile.patch";
hash = "sha256-KGnAa6euOt6dkZQwURyVITcfqTkDkSR8zpE97DywUUw=";
})
];
# FIXME: -dev depends on -doc
outputs = [
"out"
"dev"
"man"
"doc"
];
setOutputFlags = false; # it would move $out/modules, etc.
depsBuildBuild = [ buildPackages.stdenv.cc ];
nativeBuildInputs = [
autoreconfHook
pkg-config
perl
which
];
buildInputs = [
perl
libxcrypt
zlib
]
++ lib.optional brotliSupport brotli
++ lib.optional sslSupport openssl
++ lib.optional ldapSupport openldap
# there is no --with-ldap flag
++ lib.optional luaSupport lua5
++ lib.optional libxml2Support libxml2
++ lib.optional http2Support nghttp2
++ lib.optional stdenv.hostPlatform.isDarwin libiconv
++ lib.optional systemdSupport systemdLibs;
postPatch = ''
sed -i config.layout -e "s|installbuilddir:.*|installbuilddir: $dev/share/build|"
sed -i configure.in \
-e 's|AC_PATH_PROG|AC_PATH_TOOL|' \
-e 's|perlbin=.*|perlbin="/usr/bin/env perl"|'
${lib.optionalString withLynx "sed -i support/apachectl.in -e 's|@LYNX_PATH@|${lynx}/bin/lynx|'"}
'';
# Required for ‘pthread_cancel’.
env = lib.optionalAttrs (!stdenv.hostPlatform.isDarwin) {
NIX_LDFLAGS = "-lgcc_s";
};
configureFlags = [
"--with-apr=${apr.dev}"
"--with-apr-util=${aprutil.dev}"
"--with-z=${zlib.dev}"
"--with-pcre=${pcre2.dev}/bin/pcre2-config"
"--disable-maintainer-mode"
"--disable-debugger-mode"
"--enable-mods-shared=all"
"--enable-mpms-shared=all"
"--enable-cern-meta"
"--enable-imagemap"
"--enable-cgi"
"--includedir=${placeholder "dev"}/include"
"--docdir=$(doc)/share/doc"
(lib.enableFeature proxySupport "proxy")
(lib.enableFeature sslSupport "ssl")
(lib.withFeatureAs libxml2Support "libxml2" "${libxml2.dev}/include/libxml2")
(lib.enableFeature brotliSupport "brotli")
(lib.enableFeature http2Support "http2")
(lib.enableFeature systemdSupport "systemd")
(lib.enableFeature luaSupport "lua")
]
++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
# skip bad config check when cross compiling
# https://gitlab.com/buildroot.org/buildroot/-/blob/5dae8cddeecf16c791f3c138542ec51c4e627d75/package/apache/apache.mk#L23
"ap_cv_void_ptr_lt_long=no"
];
enableParallelBuilding = true;
stripDebugList = [
"lib"
"modules"
"bin"
];
postInstall = ''
mkdir -p $doc/share/doc/httpd
mv $out/manual $doc/share/doc/httpd
mkdir -p $dev/bin
mv $out/bin/apxs $dev/bin/apxs
'';
passthru = {
inherit
apr
aprutil
sslSupport
proxySupport
ldapSupport
luaSupport
lua5
;
tests = {
acme-integration = nixosTests.acme.httpd;
proxy = nixosTests.proxy;
php = nixosTests.php.httpd;
cross = runCommand "apacheHttpd-test-cross" { } ''
${pkgsCross.aarch64-multiplatform.apacheHttpd.dev}/bin/apxs -q -n INCLUDE | grep CC=aarch64-unknown-linux-gnu-gcc > $out
head -n1 ${pkgsCross.aarch64-multiplatform.apacheHttpd}/bin/dbmmanage | grep '^#!${pkgsCross.aarch64-multiplatform.perl}/bin/perl$' >> $out
'';
};
};
meta = {
description = "Apache HTTPD, the world's most popular web server";
homepage = "https://httpd.apache.org/";
license = lib.licenses.asl20;
platforms = lib.platforms.linux ++ lib.platforms.darwin;
maintainers = with lib.maintainers; [ arcayr ];
};
}
|
