blob: 597fb7f595e2d9ae0f0dca863bc857c49050d317 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
{
lib,
config,
stdenvNoCC,
xwin,
cacert,
}:
let
host = stdenvNoCC.hostPlatform;
hostArch =
if host.isx86_64 then
"x86_64"
else if host.isAarch64 then
"aarch64"
else if host.isx86_32 then
"x86"
else if host.isAarch32 then
"aarch"
else
throw "Unsupported system";
in
lib.extendMkDerivation {
constructDrv = stdenvNoCC.mkDerivation;
excludeDrvArgNames = [
"manifest"
"arch"
];
extendDrvArgs =
finalAttrs:
{
name ? "xwin-fetch-msvc",
hash ? lib.fakeHash,
manifest ? null,
arch ? hostArch,
...
}@args:
{
inherit name;
__structuredAttrs = true;
dontUnpack = true;
dontFixup = true;
dontInstall = true;
strictDeps = true;
nativeBuildInputs = [
xwin
cacert
];
outputHashAlgo = "sha256";
outputHashMode = "recursive";
outputHash =
if !config.microsoftVisualStudioLicenseAccepted then
throw ''
Microsoft Software License Terms are not accepted with config.microsoftVisualStudioLicenseAccepted.
Please read https://visualstudio.microsoft.com/license-terms/mt644918/ and if you agree, change your
config to indicate so.
''
else
hash;
xwinArgs = lib.optionals (manifest != null) [ "--manifest=${manifest}" ] ++ [
"--accept-license"
"--cache-dir=${placeholder "out"}"
"--arch=${arch}"
"download"
];
buildPhase =
args.buildPhase or ''
runHook preBuild
xwin "''${xwinArgs[@]}"
runHook postBuild
'';
passthru = {
inherit arch;
};
meta.license = {
deprecated = false;
fullName = "Microsoft Software License Terms";
shortName = "msvc";
spdxId = "unknown";
free = false;
url = "https://www.visualstudio.com/license-terms/mt644918/";
};
};
}
|
