blob: c972b2920be238ad57b735b2eb145df7f6975f80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
{
lib,
skawarePackages,
skalibs,
execline,
s6,
s6-dns,
# Whether to build the TLS/SSL tools and what library to use
# acceptable values: "bearssl", "libressl", false
sslSupport ? "bearssl",
libressl,
bearssl,
}:
let
sslSupportEnabled = sslSupport != false;
sslLibs = {
libressl = libressl;
bearssl = bearssl;
};
in
assert sslSupportEnabled -> sslLibs ? ${sslSupport};
skawarePackages.buildPackage {
pname = "s6-networking";
version = "2.8.0.1";
sha256 = "sha256-bwEcM7oFhs5Y/u4M+FSgsIfpCC/b0kq7eGFIRjgw80E=";
manpages = skawarePackages.buildManPages {
pname = "s6-networking-man-pages";
version = "2.7.2.1.4";
sha256 = "sha256-N5BXi21JEgF3X5FKg5SzKNKfzYS5uTRqbUvbsrEZ2xg=";
description = "Port of the documentation for the s6-networking suite to mdoc";
maintainers = [ lib.maintainers.sternenseemann ];
};
meta.description = "Suite of small networking utilities for Unix systems";
outputs = [
"bin"
"lib"
"dev"
"doc"
"out"
];
buildInputs = [
skalibs
execline
s6
s6-dns
]
++ lib.optional sslSupportEnabled sslLibs.${sslSupport};
# TODO: nsss support
configureFlags = [
"--libdir=${placeholder "lib"}/lib"
"--dynlibdir=${placeholder "out"}/lib"
"--libexecdir=${placeholder "lib"}/libexec"
"--bindir=${placeholder "bin"}/bin"
"--includedir=${placeholder "dev"}/include"
"--pkgconfdir=${placeholder "dev"}/lib/pkgconfig"
"--with-sysdeps=${skalibs.lib}/lib/skalibs/sysdeps"
]
++ lib.optional sslSupportEnabled "--enable-ssl=${sslSupport}";
postInstall = ''
# remove all s6 executables from build directory
rm $(find -name "s6-*" -type f -mindepth 1 -maxdepth 1 -executable) proxy-server
rm libs6net.* libstls.* libs6tls.* libsbearssl.*
mv doc $doc/share/doc/s6-networking/html
'';
}
|
