blob: d97e1f235bd5c90f6eee1c4814db44fa9158a895 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
{
lib,
callPackage,
installShellFiles,
rSrc,
version,
gawk,
binlore,
resholve,
resholve-utils,
}:
let
python27 = callPackage ./python27.nix { };
in
python27.pkgs.buildPythonApplication {
pname = "resholve";
inherit version;
src = rSrc;
nativeBuildInputs = [ installShellFiles ];
propagatedBuildInputs = with python27.pkgs; [
oildev
configargparse
sedparse
];
makeWrapperArgs = [
"--prefix"
"PATH"
":"
(lib.makeBinPath [ gawk ])
];
postPatch = ''
for file in setup.cfg _resholve/version.py; do
substituteInPlace $file --subst-var-by version ${version}
done
'';
postInstall = ''
installManPage resholve.1
'';
# Do not propagate Python; may be obsoleted by nixos/nixpkgs#102613
# for context on why, see abathur/resholve#20
postFixup = ''
rm $out/nix-support/propagated-build-inputs
'';
passthru = {
inherit (resholve-utils)
mkDerivation
phraseSolution
writeScript
writeScriptBin
;
tests = callPackage ./test.nix {
inherit
rSrc
binlore
resholve
;
};
};
__structuredAttrs = true;
meta = {
description = "Resolve external shell-script dependencies";
homepage = "https://github.com/abathur/resholve";
changelog = "https://github.com/abathur/resholve/blob/v${version}/CHANGELOG.md";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ abathur ];
platforms = lib.platforms.all;
knownVulnerabilities = [
''
resholve depends on python27 (EOL). While it's safe to
run on trusted input in the build sandbox, you should
avoid running it on untrusted input.
''
];
};
}
|
