blob: 078dd8e535bb7cbe73105bc58265bd09562451c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
{ pkgs, haskellLib }:
with haskellLib;
self: super:
let
# This contains updates to the dependencies, without which it would
# be even more work to get it to build.
# As of 2020-04, there's no new release in sight, which is why we're
# pulling from Github.
tensorflow-haskell = pkgs.fetchFromGitHub {
owner = "tensorflow";
repo = "haskell";
rev = "555d90c43202d5a3021893013bfc8e2ffff58c97";
sha256 = "uOuIeD4o+pcjvluTqyVU3GJUQ4e1+p3FhINJ9b6oK+k=";
fetchSubmodules = true;
};
setTensorflowSourceRoot =
dir: drv:
(overrideCabal (drv: { src = tensorflow-haskell; }) drv).overrideAttrs (_oldAttrs: {
sourceRoot = "${tensorflow-haskell.name}/${dir}";
});
in
{
tensorflow-proto = setTensorflowSourceRoot "tensorflow-proto" super.tensorflow-proto;
tensorflow = overrideCabal (drv: {
libraryHaskellDepends = drv.libraryHaskellDepends ++ [ self.vector-split ];
}) (setTensorflowSourceRoot "tensorflow" super.tensorflow);
tensorflow-core-ops = setTensorflowSourceRoot "tensorflow-core-ops" super.tensorflow-core-ops;
tensorflow-logging = setTensorflowSourceRoot "tensorflow-logging" super.tensorflow-logging;
tensorflow-opgen = setTensorflowSourceRoot "tensorflow-opgen" super.tensorflow-opgen;
tensorflow-ops = setTensorflowSourceRoot "tensorflow-ops" super.tensorflow-ops;
}
|
