pkgs/development/compilers/dotnet/dotnet.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{
  config,
  callPackage,
  lib,
  channel,
  dir ? ./. + ("/" + channel),
  buildDotnetSdk,
  ...
}@attrs:

let
  binary =
    let
      path = dir + "/releases.nix";
    in
    if lib.pathExists path then buildDotnetSdk path else { };

  withVMR = lib.pathExists (dir + "/release.json");

  sourcePackages = lib.optionalAttrs withVMR (callPackage ./source (attrs // { inherit binary; }));

  pkgs =
    lib.optionalAttrs config.allowAliases binary
    // lib.mapAttrs' (k: v: lib.nameValuePair "${k}-bin" v) binary
    // sourcePackages;

  suffix = lib.replaceStrings [ "." ] [ "_" ] channel;
  sdkAttr = "sdk_${suffix}" + lib.optionalString (!withVMR) "-bin";
in
pkgs
// {
  ${sdkAttr} = pkgs.${sdkAttr}.overrideAttrs (prev: {
    passthru = prev.passthru or { } // {
      updateScript = [
        ./update.sh
        channel
      ];
    };
  });
}