1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
|
{
lib,
stdenv,
fetchFromGitHub,
fontconfig,
installShellFiles,
libGL,
libx11,
libxcb,
libxkbcommon,
ncurses,
nixosTests,
openssl,
perl,
pkg-config,
python3,
runCommand,
rustPlatform,
vulkan-loader,
wayland,
wezterm,
libxcb-util,
libxcb-image,
libxcb-keysyms,
libxcb-wm,
zlib,
rcodesign,
}:
rustPlatform.buildRustPackage (finalAttrs: {
pname = "wezterm";
version = "0-unstable-2026-08-31";
src = fetchFromGitHub {
owner = "wezterm";
repo = "wezterm";
rev = "4fbd6b8e90e2326b8e25c589768f98bd71ddd047";
fetchSubmodules = true;
hash = "sha256-Fe2rH9HegaUixPXHyHv4B8c0RI34GPbeX8mTzHCQwQ4=";
};
postPatch = ''
echo ${finalAttrs.version} > .tag
# hash does not work well with NixOS
substituteInPlace assets/shell-integration/wezterm.sh \
--replace-fail 'hash wezterm 2>/dev/null' 'command type -P wezterm &>/dev/null' \
--replace-fail 'hash base64 2>/dev/null' 'command type -P base64 &>/dev/null' \
--replace-fail 'hash hostname 2>/dev/null' 'command type -P hostname &>/dev/null' \
--replace-fail 'hash hostnamectl 2>/dev/null' 'command type -P hostnamectl &>/dev/null'
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
# many tests fail with: No such file or directory
rm -r wezterm-ssh/tests
'';
# dep: syntax causes build failures in rare cases
# https://github.com/rust-secure-code/cargo-auditable/issues/124
# https://github.com/wezterm/wezterm/blob/main/nix/flake.nix#L134
auditable = false;
cargoHash = "sha256-h/qbCAEukgk1ADvn5iUfE4u596Sf+C24OsELlnCNX0g=";
nativeBuildInputs = [
installShellFiles
ncurses # tic for terminfo
pkg-config
python3
]
++ lib.optionals stdenv.hostPlatform.isDarwin [
perl
rcodesign
];
buildInputs = [
fontconfig
openssl
zlib
]
++ lib.optionals stdenv.hostPlatform.isLinux [
libx11
libxcb
libxkbcommon
wayland
libxcb-util
libxcb-image
libxcb-keysyms
libxcb-wm # contains xcb-ewmh among others
];
buildFeatures = [ "distro-defaults" ];
postInstall = ''
mkdir -p $out/nix-support
echo "${finalAttrs.passthru.terminfo}" >> $out/nix-support/propagated-user-env-packages
install -Dm644 assets/icon/terminal.png $out/share/icons/hicolor/128x128/apps/org.wezfurlong.wezterm.png
install -Dm644 assets/wezterm.desktop $out/share/applications/org.wezfurlong.wezterm.desktop
install -Dm644 assets/wezterm.appdata.xml $out/share/metainfo/org.wezfurlong.wezterm.appdata.xml
install -Dm644 assets/shell-integration/wezterm.sh -t $out/etc/profile.d
installShellCompletion --cmd wezterm \
--bash assets/shell-completion/bash \
--fish assets/shell-completion/fish \
--zsh assets/shell-completion/zsh
install -Dm644 assets/wezterm-nautilus.py -t $out/share/nautilus-python/extensions
'';
preFixup =
lib.optionalString stdenv.hostPlatform.isLinux ''
patchelf \
--add-needed "${libGL}/lib/libEGL.so.1" \
--add-needed "${vulkan-loader}/lib/libvulkan.so.1" \
$out/bin/wezterm-gui
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
mkdir -p "$out/Applications"
OUT_APP="$out/Applications/WezTerm.app"
cp -r assets/macos/WezTerm.app "$OUT_APP"
rm $OUT_APP/*.dylib
# macos codesigning requires a specific directory structure
# see also: https://github.com/wezterm/wezterm/blob/76b606ec597a3c0263fa60321548637451c0a547/ci/deploy.sh#L31
mkdir -p $OUT_APP/Contents/{MacOS,Resources}
cp -r assets/shell-integration/* $OUT_APP/Contents/Resources/
# https://github.com/wezterm/wezterm/pull/6886
# macOS will only recognize our application bundle
# if the binaries are inside of it. Move them there
# and create symbolic links for them in bin/.
mv $out/bin/{wezterm,wezterm-mux-server,wezterm-gui,strip-ansi-escapes} $OUT_APP/Contents/MacOS/
ln -s $OUT_APP/Contents/MacOS/{wezterm,wezterm-mux-server,wezterm-gui,strip-ansi-escapes} $out/bin
'';
# notifications require that the app bundle be codesigned (beyond the linker-signing that happens automatically for the executable)
postFixup = lib.optionalString stdenv.hostPlatform.isDarwin "rcodesign sign $out/Applications/WezTerm.app";
passthru = {
# the headless variant is useful when deploying wezterm's mux server on remote severs
headless = import ./headless.nix {
inherit
openssl
pkg-config
rustPlatform
wezterm
;
};
terminfo =
runCommand "wezterm-terminfo"
{
nativeBuildInputs = [ ncurses ];
}
''
mkdir -p $out/share/terminfo $out/nix-support
tic -x -o $out/share/terminfo ${finalAttrs.src}/termwiz/data/wezterm.terminfo
'';
tests = {
all-terminfo = nixosTests.allTerminfo;
# the test is commented out in nixos/tests/terminal-emulators.nix
#terminal-emulators = nixosTests.terminal-emulators.wezterm;
};
updateScript = ./update.sh;
};
meta = {
description = "GPU-accelerated cross-platform terminal emulator and multiplexer written by @wez and implemented in Rust";
homepage = "https://wezterm.org";
license = lib.licenses.mit;
mainProgram = "wezterm";
maintainers = with lib.maintainers; [ SuperSandro2000 ];
};
})
|
