blob: 8c7fc6eca9e09001266bc7e1483824f6121e6c0e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
{
lib,
fetchFromGitHub,
makeWrapper,
python3,
}:
python3.pkgs.buildPythonApplication (finalAttrs: {
pname = "volatility3";
version = "2.28.0";
pyproject = true;
src = fetchFromGitHub {
owner = "volatilityfoundation";
repo = "volatility3";
tag = "v${finalAttrs.version}";
hash = "sha256-QO3rwGlVRBWEjReIGRDTK0LPVFN+4omkvxITaFC+5e0=";
};
build-system = with python3.pkgs; [ setuptools ];
nativeBuildInputs = [ makeWrapper ];
dependencies = with python3.pkgs; [
capstone
jsonschema
pefile
pycryptodome
yara-python
];
preBuild = ''
export HOME=$(mktemp -d);
'';
postFixup = ''
for executable in vol volshell; do
wrapProgram $out/bin/$executable \
--run 'volatility3_data_dir="''${XDG_DATA_HOME:-$HOME/.local/share}/volatility3"
mkdir -p "$volatility3_data_dir/symbols"' \
--run 'volatility3_cache_dir="''${XDG_CACHE_HOME:-$HOME/.cache}/volatility3"
mkdir -p "$volatility3_cache_dir"' \
--add-flags '--symbol-dirs "''${XDG_DATA_HOME:-$HOME/.local/share}/volatility3/symbols"' \
--add-flags '--cache-path "''${XDG_CACHE_HOME:-$HOME/.cache}/volatility3"'
done
'';
# Project has no tests
doCheck = false;
pythonImportsCheck = [ "volatility3" ];
meta = {
description = "Volatile memory extraction frameworks";
homepage = "https://www.volatilityfoundation.org/";
changelog = "https://github.com/volatilityfoundation/volatility3/releases/tag/${finalAttrs.src.tag}";
license = lib.licenses.vol-sl;
maintainers = with lib.maintainers; [
caverav
fab
];
};
})
|
