blob: 5d35de4c81d2acac9d9e3ce9a5a5954d08b0a29c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
{
lib,
stdenv,
fetchurl,
fetchpatch,
autoreconfHook,
perl,
gdb,
writeScript,
}:
stdenv.mkDerivation rec {
pname = "valgrind";
version = "3.27.1";
src = fetchurl {
url = "https://sourceware.org/pub/valgrind/valgrind-${version}.tar.bz2";
hash = "sha256-XViRUuuAccAv6rjOarcZ5DGh+8PisXAPVDJjKouSZNw=";
};
patches = [
# Fix checks on Musl.
# https://bugs.kde.org/show_bug.cgi?id=453929
(fetchpatch {
url = "https://bugsfiles.kde.org/attachment.cgi?id=148912";
sha256 = "Za+7K93pgnuEUQ+jDItEzWlN0izhbynX2crSOXBBY/I=";
})
# https://bugs.kde.org/show_bug.cgi?id=511548
(fetchpatch {
url = "https://bugsfiles.kde.org/attachment.cgi?id=186451";
hash = "sha256-IGmyHwwGoy00hcz3XxQSDcwcU8zHLBJ9dfqTvWDQ520=";
})
(fetchpatch {
name = "reallocarray-test-musl.patch";
url = "https://sourceware.org/git/?p=valgrind.git;a=patch;h=991961ece87e4cdc0771a05c956c55baa437bb07";
hash = "sha256-U16384rLXMhLE5Em9z8FKYbshPlnq8l9ejC2+epL7M4=";
})
# Fix build on armv7l.
# see also https://bugs.kde.org/show_bug.cgi?id=454346
(fetchpatch {
url = "https://git.yoctoproject.org/poky/plain/meta/recipes-devtools/valgrind/valgrind/use-appropriate-march-mcpu-mfpu-for-ARM-test-apps.patch?id=b7a9250590a16f1bdc8c7b563da428df814d4292";
sha256 = "sha256-sBZzn98Sf/ETFv8ubivgA6Y6fBNcyR8beB3ICDAyAH0=";
})
];
outputs = [
"out"
"dev"
"man"
"doc"
];
hardeningDisable = [
"stackprotector"
];
# GDB is needed to provide a sane default for `--db-command'.
# Perl is needed for `callgrind_{annotate,control}'.
buildInputs = [
gdb
perl
];
# Perl is also a native build input.
nativeBuildInputs = [
autoreconfHook
perl
];
enableParallelBuilding = true;
separateDebugInfo = stdenv.hostPlatform.isLinux;
preConfigure = lib.optionalString stdenv.hostPlatform.isFreeBSD ''
substituteInPlace configure --replace-fail '`uname -r`' ${stdenv.cc.libc.version}-
'';
configureFlags = lib.optional stdenv.hostPlatform.isx86_64 "--enable-only64bit";
doCheck = true;
postInstall = ''
for i in $out/libexec/valgrind/*.supp; do
substituteInPlace $i \
--replace 'obj:/lib' 'obj:*/lib' \
--replace 'obj:/usr/X11R6/lib' 'obj:*/lib' \
--replace 'obj:/usr/lib' 'obj:*/lib'
done
'';
passthru = {
updateScript = writeScript "update-valgrind" ''
#!/usr/bin/env nix-shell
#!nix-shell -i bash -p curl pcre2 common-updater-scripts
set -eu -o pipefail
# Expect the text in format of:
# 'Current release: <a href="/downloads/current.html#current">valgrind-3.19.0</a>'
new_version="$(curl -s https://valgrind.org/ |
pcre2grep -o1 'Current release: .*>valgrind-([0-9.]+)</a>')"
update-source-version ${pname} "$new_version"
'';
};
meta = {
homepage = "https://valgrind.org/";
description = "Debugging and profiling tool suite";
longDescription = ''
Valgrind is an award-winning instrumentation framework for
building dynamic analysis tools. There are Valgrind tools that
can automatically detect many memory management and threading
bugs, and profile your programs in detail. You can also use
Valgrind to build new tools.
'';
license = lib.licenses.gpl3Plus;
mainProgram = "valgrind";
maintainers = with lib.maintainers; [ albfsg ];
platforms =
with lib.platforms;
lib.intersectLists (x86 ++ power ++ s390x ++ armv7 ++ aarch64 ++ mips ++ riscv64) (
darwin ++ freebsd ++ illumos ++ linux
);
badPlatforms = [ lib.systems.inspect.platformPatterns.isStatic ];
# See: <https://hydra.nixos.org/build/128521440/nixlog/2>
#
# Darwin‐specific derivation logic has been removed, check the
# history if you want to fix this.
broken = stdenv.hostPlatform.isDarwin;
};
}
|
