1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
{
lib,
stdenv,
fetchFromGitHub,
alsa-lib,
bzip2,
cmake,
glib,
libGL,
libsndfile,
libvpx,
libwebp,
libx11,
makeWrapper,
moltenvk,
mpg123,
ninja,
openal,
pkg-config,
python3,
sdl2-compat,
vulkan-headers,
vulkan-loader,
zlib,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "uzdoom";
version = "5.0.1";
__structuredAttrs = true;
strictDeps = true;
src = fetchFromGitHub {
owner = "UZDoom";
repo = "UZDoom";
tag = finalAttrs.version;
hash = "sha256-JaAx3HlsHPFDILQrq9rz1FpO7dVsfoJgvCLvNx8+CJ0=";
};
outputs = [ "out" ] ++ lib.optionals stdenv.hostPlatform.isLinux [ "doc" ];
postPatch = ''
substituteInPlace cmake/UpdateRevision.cmake \
--replace-fail "unknown" "${finalAttrs.src.tag}"
'';
nativeBuildInputs = [
cmake
makeWrapper
ninja
pkg-config
python3
];
buildInputs = [
bzip2
glib
libGL
libsndfile
libvpx
libwebp
mpg123
openal
sdl2-compat
vulkan-loader
zlib
]
++ lib.optionals stdenv.hostPlatform.isLinux [
alsa-lib
libx11
]
++ lib.optionals stdenv.hostPlatform.isDarwin [
moltenvk
vulkan-headers
];
cmakeFlags = [
(lib.cmakeBool "DYN_MPG123" false)
(lib.cmakeBool "DYN_OPENAL" false)
(lib.cmakeBool "DYN_SNDFILE" false)
]
++ lib.optionals stdenv.hostPlatform.isDarwin [
(lib.cmakeFeature "OPENAL_INCLUDE_DIR" "${openal}/include/AL")
(lib.cmakeFeature "OPENAL_LIBRARY" "${openal}/lib/libopenal.dylib")
(lib.cmakeFeature "Vulkan_INCLUDE_DIR" "${vulkan-headers}/include")
(lib.cmakeFeature "Vulkan_MoltenVK_INCLUDE_DIR" "${lib.getDev moltenvk}/include")
(lib.cmakeFeature "Vulkan_MoltenVK_LIBRARY" "${moltenvk}/lib/libMoltenVK.dylib")
(lib.cmakeBool "HAVE_VULKAN" true)
(lib.cmakeBool "HAVE_GLES2" false)
];
installPhase = lib.optionalString stdenv.hostPlatform.isDarwin ''
runHook preInstall
mkdir -p "$out"/{Applications,bin}
mv uzdoom.app "$out/Applications/"
makeWrapper $out/Applications/uzdoom.app/Contents/MacOS/uzdoom $out/bin/uzdoom \
--chdir $out/Applications/uzdoom.app/Contents/MacOS/
runHook postInstall
'';
postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
mv $out/bin/uzdoom $out/share/games/uzdoom/uzdoom
makeWrapper $out/share/games/uzdoom/uzdoom $out/bin/uzdoom \
--set LD_LIBRARY_PATH ${lib.makeLibraryPath [ vulkan-loader ]}
'';
meta = {
description = "Modern, feature-rich source port for the classic game DOOM";
longDescription = ''
UZDoom is a feature centric port for all Doom engine games, based on
GZDoom, adding an advanced renderer and powerful scripting capabilities
'';
homepage = "https://zdoom.org";
changelog = "https://github.com/UZDoom/UZDoom/releases/tag/${finalAttrs.version}";
license = lib.licenses.gpl3Plus;
maintainers = with lib.maintainers; [
Gliczy
keenanweaver
r4v3n6101
];
platforms = with lib.platforms; linux ++ darwin;
mainProgram = "uzdoom";
};
})
|
