blob: fe772d5bcb387b975fac67b29f76e83f517abe39 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
{
lib,
stdenv,
buildGoModule,
fetchFromGitHub,
installShellFiles,
makeWrapper,
versionCheckHook,
withQemu ? false,
qemu,
}:
buildGoModule (finalAttrs: {
pname = "talosctl";
version = "1.14.0";
src = fetchFromGitHub {
owner = "siderolabs";
repo = "talos";
tag = "v${finalAttrs.version}";
hash = "sha256-zKxP5IM0/c4ntbujIYYe91r7VfdoolHWs/CdkYOOLJU=";
};
vendorHash = "sha256-XBqBYg+/yGECsHsmZuJzliyUVcWoby/IHs2WBaMw9jo=";
postPatch = lib.optionalString withQemu ''
substituteInPlace pkg/provision/providers/qemu/arch.go \
--replace-fail '/opt/homebrew' '${lib.getLib qemu}'
'';
ldflags = [
"-s"
"-w"
];
overrideModAttrs = _: {
buildPhase = ''
go work vendor
'';
};
subPackages = [ "cmd/talosctl" ];
nativeBuildInputs = [ installShellFiles ] ++ lib.optionals withQemu [ makeWrapper ];
postInstall =
lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
installShellCompletion --cmd talosctl \
--bash <($out/bin/talosctl completion bash) \
--fish <($out/bin/talosctl completion fish) \
--zsh <($out/bin/talosctl completion zsh)
''
+ lib.optionalString withQemu ''
wrapProgram $out/bin/talosctl \
--suffix PATH : ${lib.makeBinPath [ qemu ]}
'';
doCheck = false; # no tests
doInstallCheck = true;
nativeInstallCheckInputs = [ versionCheckHook ];
versionCheckProgramArg = "version";
meta = {
description = "CLI for out-of-band management of Kubernetes nodes created by Talos";
mainProgram = "talosctl";
homepage = "https://www.talos.dev/";
license = lib.licenses.mpl20;
maintainers = with lib.maintainers; [
johanot
];
};
})
|
