1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
|
{
cctools,
copyDesktopItems,
electron_43,
fetchFromGitHub,
installShellFiles,
lib,
libicns,
libsecret,
makeBinaryWrapper,
makeDesktopItem,
nix-update-script,
node-gyp,
nodejs,
pkg-config,
python3,
stdenv,
writeDarwinBundle,
xcbuild,
fetchPnpmDeps,
pnpm_11,
pnpmConfigHook,
pnpmBuildHook,
cacert,
}:
stdenv.mkDerivation (
finalAttrs:
let
appName = "T3 Code (Alpha)";
electron = electron_43;
pnpm = pnpm_11;
desktopIcon =
if stdenv.hostPlatform.isDarwin then
"assets/prod/black-macos-1024.png"
else
"assets/prod/black-universal-1024.png";
in
{
pname = "t3code-unwrapped";
version = "0.0.40";
strictDeps = true;
__structuredAttrs = true;
src = fetchFromGitHub {
owner = "pingdotgg";
repo = "t3code";
tag = "v${finalAttrs.version}";
hash = "sha256-J8kXpfMfm03/DDAiWXJuANwUNDshhiUn7Lf9tV42Xfw=";
};
postPatch = ''
substituteInPlace apps/web/vite.config.ts \
--replace-fail 'const host = explicitHost || "localhost";' \
'const host = explicitHost || "127.0.0.1";'
'';
nativeBuildInputs = [
installShellFiles
makeBinaryWrapper
node-gyp
nodejs
python3
pnpmConfigHook
pnpmBuildHook
pnpm
cacert
]
++ lib.optionals stdenv.hostPlatform.isLinux [
copyDesktopItems
pkg-config
]
++ lib.optionals stdenv.hostPlatform.isDarwin [
cctools.libtool
libicns
writeDarwinBundle
xcbuild
];
buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ libsecret ];
pnpmWorkspaces = [
# `...` suffix is used to also include other workspace packages that are
# directly or indirectly depended on by the listed packages, such as
# `@t3tools/contracts` and `@t3tools/shared`.
"@t3tools/monorepo"
"t3..."
"@t3tools/desktop..."
"@t3tools/scripts..."
];
pnpmDeps = fetchPnpmDeps {
inherit pnpm;
inherit (finalAttrs)
pname
version
src
pnpmWorkspaces
;
fetcherVersion = 4;
hash = "sha256-+UsoURSM4VP+CgF1fWROBEB85EuH+iJJM/xDPFigCKk=";
};
preBuild = ''
# pnpm 11 otherwise detects the package version updates below as
# dependency drift and runs another install, including lifecycle scripts.
export pnpm_config_verify_deps_before_run=false
node scripts/update-release-package-versions.ts ${finalAttrs.version}
export npm_config_nodedir=${nodejs}
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
# Exclude the `@t3tools/monorepo` workspace from the pending rebuild since
# `vp config` needs git
pnpm rebuild --pending "''${pnpmInstallFlags[@]}" --filter '!@t3tools/monorepo'
'';
pnpmBuildScript = "build:desktop";
postBuild = ''
pnpm vp cache clean
'';
# Many dependencies vendors many prebuilt native artifacts for non-host
# platforms, and some of those binaries are statically linked. Let fixup
# handle wrappers, shebangs, and stripping, but skip patchelf on the
# vendored tree.
dontPatchELF = true;
# The tmpdir audit hook also shells out to patchelf while scanning every
# vendored ELF for leaked build paths. That produces spurious warnings on
# some dependencies' static foreign-platform binaries.
noAuditTmpdir = true;
installPhase = ''
runHook preInstall
mkdir --parents "$out"/libexec/t3code/apps/desktop "$out"/libexec/t3code/apps/server
cp --recursive --no-preserve=mode node_modules "$out"/libexec/t3code
cp --recursive --no-preserve=mode apps/server/{node_modules,dist} "$out"/libexec/t3code/apps/server
cp --recursive --no-preserve=mode \
apps/desktop/{package.json,node_modules,dist-electron} \
"$out"/libexec/t3code/apps/desktop
mkdir --parents "$out"/libexec/t3code/apps/desktop/prod-resources
install --mode=444 ${desktopIcon} \
"$out"/libexec/t3code/apps/desktop/prod-resources/icon.png
''
+ lib.optionalString stdenv.hostPlatform.isLinux ''
install -Dm755 \
native/browser-secret/build/${stdenv.hostPlatform.node.arch}/t3-browser-secret \
"$out"/libexec/t3code/apps/desktop/prod-resources/browser-secret/t3-browser-secret
''
+ ''
find "$out"/libexec/t3code -xtype l -delete
makeWrapper ${lib.getExe nodejs} "$out"/bin/t3 \
--add-flags "$out"/libexec/t3code/apps/server/dist/bin.mjs
makeWrapper ${lib.getExe electron} "$out"/bin/t3code-desktop \
--add-flags "$out"/libexec/t3code/apps/desktop \
--inherit-argv0
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
# node-pty tries to chmod this helper at runtime, but the Nix store is
# immutable by then.
find "$out"/libexec/t3code \
-path '*/node-pty/prebuilds/darwin-*/spawn-helper' \
-exec chmod 755 {} +
mkdir --parents "$out/Applications/${appName}.app/Contents/"{MacOS,Resources}
png2icns \
"$out/Applications/${appName}.app/Contents/Resources/t3code.icns" \
${desktopIcon}
# writeDarwinBundle is a shebangless bash script; run it explicitly via
# stdenv.shell to avoid Darwin's intermittent ENOEXEC fallback issues.
${stdenv.shell} ${lib.getExe writeDarwinBundle} \
"$out" "${appName}" t3code-desktop t3code
''
+ ''
mkdir --parents \
"$out"/share/icons/hicolor/scalable/apps
install --mode=444 ${desktopIcon} \
"$out"/share/icons/t3code.png
install --mode=444 assets/prod/logo.svg \
"$out"/share/icons/hicolor/scalable/apps/t3code.svg
runHook postInstall
'';
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
for shell in bash fish zsh; do
installShellCompletion --cmd t3 --"$shell" <("$out/bin/t3" --completions "$shell")
done
'';
desktopItems = [
(makeDesktopItem {
name = "t3code";
desktopName = appName;
comment = "Minimal web GUI for coding agents";
exec = "t3code-desktop %U";
terminal = false;
icon = "t3code";
startupWMClass = "t3code";
categories = [ "Development" ];
})
];
passthru = {
updateScript = nix-update-script {
attrPath = "t3code.unwrapped";
extraArgs = [ "--use-github-releases" ];
};
};
meta = {
description = "Minimal web GUI for coding agents";
homepage = "https://t3.codes";
downloadPage = "https://t3.codes/download";
changelog = "https://github.com/pingdotgg/t3code/releases/tag/${finalAttrs.src.tag}";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [
iamanaws
qweered
];
mainProgram = "t3code-desktop";
inherit (nodejs.meta) platforms;
};
}
)
|
