blob: b83396307d54314266b89d4d7de0a982f6a1bce8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{
buildGoModule,
fetchFromGitHub,
lib,
nix-update-script,
testers,
symfony-cli,
nssTools,
makeBinaryWrapper,
installShellFiles,
}:
buildGoModule (finalAttrs: {
pname = "symfony-cli";
version = "5.20.0";
vendorHash = "sha256-YFcv+lmD8TZUsN2zYK1usfuLVqzGYdsJ+ScDRcpSORs=";
src = fetchFromGitHub {
owner = "symfony-cli";
repo = "symfony-cli";
tag = "v${finalAttrs.version}";
hash = "sha256-NrkD+Upv8PaeaVEQUEVVl2e8jKSr3qoro7fB6MkA95w=";
leaveDotGit = true;
postFetch = ''
git --git-dir $out/.git log -1 --pretty=%cd --date=format:'%Y-%m-%dT%H:%M:%SZ' > $out/SOURCE_DATE
rm -rf $out/.git
'';
};
ldflags = [
"-s"
"-w"
"-X main.version=${finalAttrs.version}"
"-X main.channel=stable"
];
preBuild = ''
ldflags+=" -X main.buildDate=$(cat SOURCE_DATE)"
'';
buildInputs = [ makeBinaryWrapper ];
nativeBuildInputs = [ installShellFiles ];
postInstall = ''
mkdir $out/libexec
mv $out/bin/symfony-cli $out/libexec/symfony
makeBinaryWrapper $out/libexec/symfony $out/bin/symfony \
--prefix PATH : ${lib.makeBinPath [ nssTools ]}
installShellCompletion --cmd symfony \
--bash <($out/bin/symfony completion bash) \
--fish <($out/bin/symfony completion fish) \
--zsh <($out/bin/symfony completion zsh)
'';
# Tests require network access
doCheck = false;
passthru = {
updateScript = nix-update-script { };
tests.version = testers.testVersion {
inherit (finalAttrs) version;
package = symfony-cli;
command = "symfony version --no-ansi";
};
};
meta = {
changelog = "https://github.com/symfony-cli/symfony-cli/releases/tag/v${finalAttrs.version}";
description = "Symfony CLI";
homepage = "https://github.com/symfony-cli/symfony-cli";
license = lib.licenses.agpl3Plus;
mainProgram = "symfony";
maintainers = with lib.maintainers; [ patka ];
};
})
|
