1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
{
lib,
stdenv,
nixosTests,
fetchFromGitHub,
fetchYarnDeps,
yarnConfigHook,
rustPlatform,
nodejs,
pdfium,
openssl,
dbus,
glib,
gtk3,
webkitgtk_4_1,
cacert,
pkg-config,
makeWrapper,
nix-update-script,
}:
rustPlatform.buildRustPackage (finalAttrs: {
pname = "stump";
version = "0.1.7";
src = fetchFromGitHub {
owner = "stumpapp";
repo = "stump";
tag = "v${finalAttrs.version}";
hash = "sha256-ERERTzoh0RoWtVNrOejiyFu7ZmSVgUVGFaTsj36Je48=";
};
frontend = stdenv.mkDerivation (_: {
pname = "stump-frontend";
inherit (finalAttrs) src version;
yarnOfflineCache = fetchYarnDeps {
yarnLock = finalAttrs.src + "/yarn.lock";
hash = "sha256-x5aZLRhNmoxcrMOQNvNDfuJCfc0ezYazVGm17v3CwqE=";
};
nativeBuildInputs = [
yarnConfigHook
nodejs
];
buildPhase = ''
runHook preBuild
pushd apps/web
node ./node_modules/.bin/vite build
popd
runHook postBuild
'';
installPhase = ''
mv ./apps/web/dist $out
'';
});
__structuredAttrs = true;
cargoHash = "sha256-4qCxyoo1WyurXLEw5Nq291Tglds0Lg1LGHfgZxsoZBQ=";
cargoBuildFlags = [
"--package"
"stump_server"
"--bin"
"stump_server"
];
env.GIT_REV = "v${finalAttrs.version}";
nativeBuildInputs = [
pkg-config
makeWrapper
];
nativeCheckInputs = [
cacert
];
buildInputs = [
openssl
dbus
glib
gtk3
webkitgtk_4_1
];
preCheck = ''
export HOME=$TMP
'';
postInstall = ''
wrapProgram $out/bin/stump_server \
--set-default STUMP_CONFIG_DIR /var/lib/stump/config \
--set-default STUMP_CLIENT_DIR ${finalAttrs.frontend} \
--set-default STUMP_PORT 10001 \
--set-default STUMP_PROFILE release \
--set-default PDFIUM_PATH ${pdfium}/lib/libpdfium.so \
--set-default API_VERSION v1
'';
passthru = {
tests = nixosTests.stump;
updateScript = nix-update-script {
extraArgs = [
"--subpackage"
"frontend"
];
};
};
meta = {
homepage = "https://stumpapp.dev/";
description = "A free and open source comics, manga and digital book server with OPDS support";
license = lib.licenses.mit;
platforms = lib.platforms.all;
mainProgram = "stump_server";
maintainers = with lib.maintainers; [
jvanbruegge
tr3foil
];
};
})
|
