1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
{
lib,
stdenv,
fetchFromGitHub,
fetchpatch,
cmake,
perl,
wrapGAppsHook3,
qt6,
qt6Packages,
calcmysky,
indilib,
libnova,
exiv2,
nlopt,
testers,
xvfb-run,
gitUpdater,
md4c,
withQtWebEngine ? lib.meta.availableOn stdenv.hostPlatform qt6.qtwebengine,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "stellarium";
version = "26.2";
src = fetchFromGitHub {
owner = "Stellarium";
repo = "stellarium";
tag = "v${finalAttrs.version}";
hash = "sha256-mNm79atM7G3p6jHmoK9Ix1+el1jP8ZNJHRaXcbObbdg=";
};
patches = [
(fetchpatch {
url = "https://gitlab.archlinux.org/archlinux/packaging/packages/stellarium/-/raw/ab559b6e9349569278f83c2dfc83990e971a8cb2/qt-6.10.patch";
hash = "sha256-a7zC9IQOj93VnPy8Bj/fLe4oJux7I4Edgj5OaKI4TZU=";
})
];
postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
substituteInPlace CMakeLists.txt \
--replace-fail 'SET(CMAKE_INSTALL_PREFIX "''${PROJECT_BINARY_DIR}/Stellarium.app/Contents")' \
'SET(CMAKE_INSTALL_PREFIX "${placeholder "out"}/Applications/Stellarium.app/Contents")'
substituteInPlace src/CMakeLists.txt \
--replace-fail "\''${_qt_bin_dir}/../" "${qt6.qtmultimedia}/lib/qt-6/"
'';
nativeBuildInputs = [
cmake
perl
wrapGAppsHook3
qt6.wrapQtAppsHook
qt6.qttools
];
buildInputs = [
qt6.qtbase
qt6.qtcharts
qt6.qtpositioning
qt6.qtmultimedia
qt6.qtserialport
calcmysky
qt6Packages.qxlsx
indilib
libnova
exiv2
md4c
nlopt
]
++ lib.optionals stdenv.hostPlatform.isLinux [
qt6.qtwayland
]
++ lib.optionals withQtWebEngine [
qt6.qtwebengine
];
preConfigure = ''
export SOURCE_DATE_EPOCH=$(date -d 20${lib.versions.major finalAttrs.version}0101 +%s)
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
export LC_ALL=en_US.UTF-8
'';
# fatal error: 'QtSerialPort/QSerialPortInfo' file not found
env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isDarwin "-F${qt6.qtserialport}/lib";
dontWrapGApps = true;
postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
makeWrapper $out/Applications/Stellarium.app/Contents/MacOS/Stellarium $out/bin/stellarium
'';
preFixup = ''
qtWrapperArgs+=("''${gappsWrapperArgs[@]}")
'';
passthru = {
tests.version = testers.testVersion {
package = finalAttrs.finalPackage;
command = ''
# Create a temporary home directory because stellarium aborts with an
# error if it can't write some configuration files.
tmpdir=$(mktemp -d)
# stellarium can't be run in headless mode, therefore we need xvfb-run.
HOME="$tmpdir" ${lib.getExe xvfb-run} stellarium --version
'';
};
updateScript = gitUpdater { rev-prefix = "v"; };
};
meta = {
description = "Free open-source planetarium";
mainProgram = "stellarium";
homepage = "https://stellarium.org/";
license = lib.licenses.gpl2Plus;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ kilianar ];
broken = stdenv.hostPlatform.isDarwin;
};
})
|
