1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
|
{
lib,
stdenv,
fetchurl,
bzip2,
gfortran,
libx11,
libxmu,
libxt,
libjpeg,
libpng,
libtiff,
ncurses,
pango,
pcre2,
perl,
readline,
tcl,
texliveSmall,
tk,
xz,
zlib,
less,
texinfo,
graphviz,
icu,
pkg-config,
bison,
which,
jdk,
blas,
lapack,
curl,
tzdata,
withRecommendedPackages ? false,
enableStrictBarrier ? false,
enableMemoryProfiling ? false,
# R as of writing does not support outputting both .so and .a files; it outputs:
# --enable-R-static-lib conflicts with --enable-R-shlib and will be ignored
static ? false,
testers,
}:
assert (!blas.isILP64) && (!lapack.isILP64);
stdenv.mkDerivation (finalAttrs: {
pname = "R";
version = "4.6.1";
src =
let
inherit (finalAttrs) pname version;
in
fetchurl {
url = "https://cran.r-project.org/src/base/R-${lib.versions.major version}/${pname}-${version}.tar.gz";
hash = "sha256-TabmHSwKrF8UoufkMstfzCae/oPaQpMFC6fwPf9OLPQ=";
};
outputs = [
"out"
"man"
"tex"
];
nativeBuildInputs = [
bison
perl
pkg-config
tzdata
which
];
buildInputs = [
bzip2
gfortran
libx11
libxmu
libxt
libxt
libjpeg
libpng
libtiff
ncurses
pango
pcre2
readline
(texliveSmall.withPackages (
ps: with ps; [
inconsolata
helvetic
ps.texinfo
fancyvrb
cm-super
rsfs
]
))
xz
zlib
less
texinfo
graphviz
icu
which
blas
lapack
curl
tcl
tk
jdk
];
strictDeps = true;
patches = [
./no-usr-local-search-paths.patch
];
# Test of the examples for package 'tcltk' fails in Darwin sandbox. See:
# https://github.com/NixOS/nixpkgs/issues/146131
postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
substituteInPlace configure \
--replace-fail "-install_name libRblas.dylib" "-install_name $out/lib/R/lib/libRblas.dylib" \
--replace-fail "-install_name libRlapack.dylib" "-install_name $out/lib/R/lib/libRlapack.dylib" \
--replace-fail "-install_name libR.dylib" "-install_name $out/lib/R/lib/libR.dylib"
substituteInPlace tests/Examples/Makefile.in \
--replace-fail "test-Examples: test-Examples-Base" "test-Examples:" # do not test the examples
substituteInPlace tests/reg-tests-1e.R \
--replace-fail 'require("tcltk")' 'F'
'';
dontDisableStatic = static;
preConfigure = ''
configureFlagsArray=(
--disable-lto
--with${lib.optionalString (!withRecommendedPackages) "out"}-recommended-packages
--with-blas="-L${blas}/lib -lblas"
--with-lapack="-L${lapack}/lib -llapack"
--with-readline
--with-tcltk --with-tcl-config="${tcl}/lib/tclConfig.sh" --with-tk-config="${tk}/lib/tkConfig.sh"
--with-cairo
--with-libpng
--with-jpeglib
--with-libtiff
--with-ICU
${lib.optionalString enableStrictBarrier "--enable-strict-barrier"}
${lib.optionalString enableMemoryProfiling "--enable-memory-profiling"}
${if static then "--enable-R-static-lib" else "--enable-R-shlib"}
AR=$(type -p ar)
AWK=$(type -p gawk)
CC=$(type -p cc)
CXX=$(type -p c++)
FC="${gfortran}/bin/gfortran" F77="${gfortran}/bin/gfortran"
JAVA_HOME="${jdk}"
RANLIB=$(type -p ranlib)
CURL_CONFIG="${lib.getExe' (lib.getDev curl) "curl-config"}"
r_cv_have_curl728=yes
R_SHELL="${stdenv.shell}"
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
--disable-R-framework
--without-x
--without-static-cairo
OBJC="clang"
CPPFLAGS="-isystem ${lib.getInclude stdenv.cc.libcxx}/include/c++/v1"
LDFLAGS="-L${lib.getLib stdenv.cc.libcxx}/lib"
''
+ ''
)
echo >>etc/Renviron.in 'TCLLIBPATH="${tk}/lib ''${TCLLIBPATH}"'
echo >>etc/Renviron.in 'TZDIR=${tzdata}/share/zoneinfo'
'';
installTargets = [
"install"
"install-info"
"install-pdf"
];
# move tex files to $tex for use with texlive.combine
# add link in $out since ${R_SHARE_DIR}/texmf is hardcoded in several places
postInstall = ''
mv -T "$out/lib/R/share/texmf" "$tex"
ln -s "$tex" "$out/lib/R/share/texmf"
'';
# The store path to "which" is baked into src/library/base/R/unix/system.unix.R,
# but Nix cannot detect it as a run-time dependency because the installed file
# is compiled and compressed, which hides the store path.
postFixup = ''
echo ${which} > $out/nix-support/undetected-runtime-dependencies
${lib.optionalString stdenv.hostPlatform.isLinux ''find $out -name "*.so" -exec patchelf {} --add-rpath $out/lib/R/lib \;''}
'';
doCheck = true;
preCheck = "export HOME=$TMPDIR; export TZ=CET; bin/Rscript -e 'sessionInfo()'";
enableParallelBuilding = true;
setupHook = ./setup-hook.sh;
passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
# dependencies (based on \RequirePackage in jss.cls, Rd.sty, Sweave.sty)
passthru.tlDeps = ps: [
ps.amsfonts
ps.amsmath
ps.fancyvrb
ps.graphics
ps.hyperref
ps.iftex
ps.jknapltx
ps.latex
ps.lm
ps.tools
ps.upquote
ps.url
];
meta = {
homepage = "http://www.r-project.org/";
description = "Free software environment for statistical computing and graphics";
mainProgram = "R";
license = lib.licenses.gpl2Plus;
longDescription = ''
GNU R is a language and environment for statistical computing and
graphics that provides a wide variety of statistical (linear and
nonlinear modelling, classical statistical tests, time-series
analysis, classification, clustering, ...) and graphical
techniques, and is highly extensible. One of R's strengths is the
ease with which well-designed publication-quality plots can be
produced, including mathematical symbols and formulae where
needed. R is an integrated suite of software facilities for data
manipulation, calculation and graphical display. It includes an
effective data handling and storage facility, a suite of operators
for calculations on arrays, in particular matrices, a large,
coherent, integrated collection of intermediate tools for data
analysis, graphical facilities for data analysis and display
either on-screen or on hardcopy, and a well-developed, simple and
effective programming language which includes conditionals, loops,
user-defined recursive functions and input and output facilities.
'';
pkgConfigModules = [ "libR" ];
platforms = lib.platforms.all;
maintainers = with lib.maintainers; [ jbedo ];
teams = [ lib.teams.sage ];
};
})
|
