1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
{
lib,
stdenv,
fetchFromGitLab,
testers,
gitUpdater,
boost,
cmake,
coreutils,
doxygen,
graphviz,
gtest,
lomiri,
properties-cpp,
pkg-config,
withDocumentation ? true,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "process-cpp";
version = "3.1.0";
src = fetchFromGitLab {
owner = "ubports";
repo = "development/core/lib-cpp/process-cpp";
rev = finalAttrs.version;
hash = "sha256-hS9V1SLO1eaIFz6ppF87c0kXHHQq6ZPOxfr00XuvWhQ=";
};
outputs = [
"out"
"dev"
]
++ lib.optionals withDocumentation [
"doc"
];
postPatch = ''
substituteInPlace data/process-cpp.pc.in \
--replace-fail 'libdir=''${exec_prefix}' 'libdir=''${prefix}' \
--replace-fail 'includedir=''${exec_prefix}' 'includedir=''${prefix}'
substituteInPlace tests/posix_process_test.cpp \
--replace-fail '/usr/bin/sleep' '${lib.getExe' coreutils "sleep"}' \
--replace-fail '/usr/bin/env' '${lib.getExe' coreutils "env"}'
'';
strictDeps = true;
nativeBuildInputs = [
cmake
pkg-config
]
++ lib.optionals withDocumentation [
doxygen
graphviz
];
buildInputs = [
boost
lomiri.cmake-extras
properties-cpp
];
checkInputs = [ gtest ];
cmakeFlags = [
(lib.cmakeBool "BUILD_TESTING" finalAttrs.finalPackage.doCheck)
(lib.cmakeBool "PROCESS_CPP_ENABLE_DOC_GENERATION" withDocumentation)
];
doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
passthru = {
tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
updateScript = gitUpdater { };
};
meta = {
description = "Simple convenience library for handling processes in C++11";
homepage = "https://gitlab.com/ubports/development/core/lib-cpp/process-cpp";
license = with lib.licenses; [
gpl3Only
lgpl3Only
];
maintainers = with lib.maintainers; [
onny
OPNA2608
];
platforms = lib.platforms.linux;
pkgConfigModules = [ "process-cpp" ];
};
})
|
