blob: b2d8f901cd46faca379f3b389cac7677fe84d27f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
{
lib,
stdenv,
fetchFromGitHub,
fetchYarnDeps,
yarnConfigHook,
yarnBuildHook,
yarnInstallHook,
nodejs,
nix-update-script,
runCommand,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "prettierd";
version = "0.28.0";
src = fetchFromGitHub {
owner = "fsouza";
repo = "prettierd";
tag = "v${finalAttrs.version}";
hash = "sha256-nPaf5p+/ryhEefkiHW9MUk2An/pIQ1UQqW9LeBojAmg=";
};
offlineCache = fetchYarnDeps {
yarnLock = finalAttrs.src + "/yarn.lock";
hash = "sha256-Z0IOyp70150zAB7CDvyw87rnzoxNdEuTMZTR6/9QP7U=";
};
strictDeps = true;
nativeBuildInputs = [
yarnConfigHook
yarnBuildHook
yarnInstallHook
nodejs
];
# launch the daemon with the same node version used to run the CLI
# fixes "Error: spawn node ENOENT" if node isn't available on the user's path
postInstall = ''
wrapProgram $out/bin/prettierd \
--prefix PATH : ${lib.makeBinPath [ nodejs ]}
'';
passthru = {
updateScript = nix-update-script { };
tests = lib.optionalAttrs (!stdenv.hostPlatform.isDarwin) {
format =
runCommand "prettierd-format-file-test" { nativeBuildInputs = [ finalAttrs.finalPackage ]; }
''
export HOME=$(mktemp -d)
prettierd ${finalAttrs.src}/package.json < ${finalAttrs.src}/package.json > $out
'';
};
};
meta = {
mainProgram = "prettierd";
description = "Prettier, as a daemon, for improved formatting speed";
homepage = "https://github.com/fsouza/prettierd";
license = lib.licenses.isc;
changelog = "https://github.com/fsouza/prettierd/blob/${finalAttrs.src.rev}/CHANGELOG.md";
platforms = with lib.platforms; linux ++ darwin;
maintainers = with lib.maintainers; [
NotAShelf
n3oney
];
};
})
|
