blob: 4bfcc81eea7c1aa415ed7e12445d325ca99abdd5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
{
lib,
stdenv,
fetchFromGitHub,
godot_4_5,
nix-update-script,
}:
let
presets = {
"i686-linux" = "Linux 32-bit";
"x86_64-linux" = "Linux 64-bit";
"aarch64-linux" = "Linux ARM64";
};
preset =
presets.${stdenv.hostPlatform.system}
or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
godot = godot_4_5;
in
stdenv.mkDerivation (finalAttrs: {
pname = "pixelorama";
version = "1.1.8";
src = fetchFromGitHub {
owner = "Orama-Interactive";
repo = "Pixelorama";
rev = "v${finalAttrs.version}";
hash = "sha256-21DNwr5D8Bl2fkMnOtyB3tZrYS/1yZAxo9OkCqV+SYs=";
};
strictDeps = true;
nativeBuildInputs = [
godot
];
# Pixelorama is tightly coupled to the version of Godot that it is meant to be built with,
# and Godot does not follow semver, they break things in minor releases.
preConfigure = ''
godot_ver="${lib.versions.majorMinor godot.version}"
godot_expected=$(sed -n -E 's@config/features=PackedStringArray\("([0-9]+\.[0-9]+)"\)@\1@p' project.godot)
[ "$godot_ver" == "$godot_expected" ] || {
echo "Expected Godot version: $godot_expected; found: $godot_ver" >&2
exit 1
}
'';
buildPhase = ''
runHook preBuild
export HOME=$(mktemp -d)
mkdir -p $HOME/.local/share/godot/
ln -s "${godot.export-template}"/share/godot/export_templates "$HOME"/.local/share/godot/
mkdir -p build
godot4 --headless --export-release "${preset}" ./build/pixelorama
runHook postBuild
'';
installPhase = ''
runHook preInstall
install -D -m 755 -t $out/libexec ./build/pixelorama
install -D -m 644 -t $out/libexec ./build/pixelorama.pck
install -D -m 644 -t $out/share/applications ./Misc/Linux/com.orama_interactive.Pixelorama.desktop
install -D -m 644 -T ./assets/graphics/icons/icon.png $out/share/icons/hicolor/256x256/apps/pixelorama.png
install -d -m 755 $out/bin
ln -s $out/libexec/pixelorama $out/bin/pixelorama
runHook postInstall
'';
passthru.updateScript = nix-update-script { };
meta = {
homepage = "https://orama-interactive.itch.io/pixelorama";
description = "Free & open-source 2D sprite editor, made with the Godot Engine";
changelog = "https://github.com/Orama-Interactive/Pixelorama/blob/${finalAttrs.src.rev}/CHANGELOG.md";
license = lib.licenses.mit;
platforms = [
"i686-linux"
"x86_64-linux"
"aarch64-linux"
];
maintainers = with lib.maintainers; [ felschr ];
mainProgram = "pixelorama";
};
})
|
