1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
|
{
lib,
stdenv,
fetchFromGitHub,
buildGoModule,
makeWrapper,
cacert,
moreutils,
jq,
git,
pkg-config,
runCommand,
nodejs_22,
nodejs-slim_22,
node-gyp,
libsecret,
libkrb5,
libx11,
libxkbfile,
ripgrep,
cctools,
nixosTests,
prefetch-npm-deps,
}:
let
nodejs = nodejs_22;
system = stdenv.hostPlatform.system;
vsBuildTarget =
{
x86_64-linux = "linux-x64";
aarch64-linux = "linux-arm64";
aarch64-darwin = "darwin-arm64";
}
.${system} or (throw "Unsupported system ${system}");
in
stdenv.mkDerivation (finalAttrs: {
pname = "openvscode-server";
version = "1.109.5";
executableName = "openvscode-server";
longName = "OpenVSCode Server";
src = fetchFromGitHub {
owner = "gitpod-io";
repo = "openvscode-server";
rev = "openvscode-server-v${finalAttrs.version}";
hash = "sha256-FWexstn6pmKPkMuoXOWr4+levM+3FK74q1HLu4kFWTc=";
};
## fetchNpmDeps doesn't correctly process git dependencies
## presumably because of https://github.com/npm/cli/issues/5170
## therefore, we're fetching all the node_module folders into
## a single FOD, and unpack it in configurePhase
nodeModules =
runCommand "openvscode-server-node-modules"
{
inherit (finalAttrs) src nativeBuildInputs;
outputHashMode = "recursive";
outputHashAlgo = "sha256";
outputHash = "sha256-DMjqFMdp7ocGdvMEmrKqB8RhF+BTN/9ybOKQAeuSG/o=";
env = {
FORCE_EMPTY_CACHE = true;
FORCE_GIT_DEPS = true;
npm_config_progress = false;
npm_config_cafile = "${cacert}/etc/ssl/certs/ca-bundle.crt";
};
}
''
runPhase unpackPhase
export HOME=$TMPDIR/home
mkdir $out
for p in $(find -name package-lock.json)
do (
echo "Prefetching $p"
${prefetch-npm-deps}/bin/prefetch-npm-deps "$p" "$out/$(dirname $p)"
)
done
'';
env = {
NODE_OPTIONS = "--openssl-legacy-provider";
NODE_ENV = "development";
# skip unnecessary binary downloads
PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD = "1";
ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
# ensure the correct node-gyp (from nixpkgs) is used
NIX_NODEJS_BUILDNPMPACKAGE = "1";
npm_config_nodedir = nodejs;
npm_config_node_gyp = "${nodejs}/lib/node_modules/npm/node_modules/node-gyp/bin/node-gyp.js";
npm_config_offline = true;
npm_config_progress = false;
# for --fixup-lockfile
prefetchNpmDeps = "${prefetch-npm-deps}/bin/prefetch-npm-deps";
forceGitDeps = true;
};
nativeBuildInputs = [
nodejs
nodejs-slim_22.python
pkg-config
makeWrapper
git
jq
moreutils
];
buildInputs =
lib.optionals (!stdenv.hostPlatform.isDarwin) [ libsecret ]
++ [
libx11
libxkbfile
libkrb5
]
++ lib.optionals stdenv.hostPlatform.isDarwin [
cctools
];
# remove all built-in extensions, as these are 3rd party extensions that
# get downloaded from vscode marketplace
postPatch = ''
jq --slurp '.[0] * .[1]' "product.json" <(
cat << EOF
{
"builtInExtensions": []
}
EOF
) | sponge product.json
echo "Updated product.json"
''
## build/lib/node.ts picks up nodejs version from remote/.npmrc
## and prefetches it into .build/node/v{version}/{target}/node
## so we pre-seed it here
+ ''
sed -i 's/target=.*/target="${nodejs.version}"/' remote/.npmrc
mkdir -p .build/node/v${nodejs.version}/${vsBuildTarget}
ln -s ${nodejs}/bin/node .build/node/v${nodejs.version}/${vsBuildTarget}/node
'';
preConfigure = ''
export HOME=$TMPDIR/home
mkdir -p $HOME
mkdir -p $TMPDIR
cp -R $nodeModules $TMPDIR/cache
chmod -R +w $TMPDIR/cache
'';
configurePhase = ''
runHook preConfigure
''
## unpack all of the prefetched node_modules folders
+ ''
for p in $(find -name package-lock.json -exec dirname {} \;)
do (
echo "Setting up $p/node_modules"
cd $p
if [ -e node_modules ]
then
echo >&2 "File exists $p/node_modules"
exit 0
fi
npm_config_cache=$TMPDIR/cache/$p npm ci --ignore-scripts
patchShebangs node_modules
)
done
''
## put ripgrep binary into bin so postinstall does not try to download it
+ ''
find -path "*@vscode/ripgrep" -type d \
-execdir mkdir -p {}/bin \; \
-execdir ln -s ${ripgrep}/bin/rg {}/bin/rg \;
''
## pre-seed node-gyp
+ ''
mkdir -p $HOME/.node-gyp/${nodejs.version}
echo 11 > $HOME/.node-gyp/${nodejs.version}/installVersion
ln -sfv ${nodejs}/include $HOME/.node-gyp/${nodejs.version}
''
## node-pty build fix
+ ''
find -path node_modules/node-pty/scripts/gen-compile-commands.js \
-exec substituteInPlace {} \
--replace-fail "npx node-gyp" "$npm_config_node_gyp" \
\;
''
## run postinstall scripts
+ ''
find -name package.json -type f -exec sh -c '
if jq -e ".scripts.postinstall" {} >-
then
echo >&2 "Running postinstall script in $(dirname {})"
npm --prefix=$(dirname {}) run postinstall
fi
exit 0
' \;
''
## rebuild native binaries
+ ''
echo >&2 "Rebuilding from source in ./remote"
npm --prefix ./remote rebuild --build-from-source
''
+ ''
runHook postConfigure
'';
buildPhase = ''
runHook preBuild
npm run gulp vscode-reh-web-${vsBuildTarget}-min
runHook postBuild
'';
installPhase = ''
runHook preInstall
mkdir -p $out
cp -R -T ../vscode-reh-web-${vsBuildTarget} $out
ln -sf ${nodejs}/bin/node $out
runHook postInstall
'';
passthru.tests = {
inherit (nixosTests) openvscode-server;
};
meta = {
description = "Run VS Code on a remote machine";
longDescription = ''
Run upstream VS Code on a remote machine with access through a modern web
browser from any device, anywhere.
'';
homepage = "https://github.com/gitpod-io/openvscode-server";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [
dguenther
emilytrau
];
platforms = [
"x86_64-linux"
"aarch64-linux"
"aarch64-darwin"
];
mainProgram = "openvscode-server";
};
})
|
