1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
{
lib,
stdenv,
fetchFromGitHub,
cmake,
libdeflate,
libunistring,
ncurses,
pandoc,
pkg-config,
zlib,
multimediaSupport ? true,
ffmpeg,
qrcodegenSupport ? true,
qrcodegen,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "notcurses";
version = "3.0.17";
src = fetchFromGitHub {
owner = "dankamongmen";
repo = "notcurses";
rev = "v${finalAttrs.version}";
sha256 = "sha256-HbyQmuxwfEWlSe/y6w0ZRui0NCFYb0SJh7YA6PC3jdY=";
};
outputs = [
"out"
"dev"
];
nativeBuildInputs = [
cmake
pandoc
pkg-config
];
buildInputs = [
libdeflate
libunistring
ncurses
zlib
]
++ lib.optional qrcodegenSupport qrcodegen
++ lib.optional multimediaSupport ffmpeg;
cmakeFlags =
lib.optional qrcodegenSupport "-DUSE_QRCODEGEN=ON"
++ lib.optional (!multimediaSupport) "-DUSE_MULTIMEDIA=none";
# https://github.com/dankamongmen/notcurses/issues/2661
postPatch = ''
substituteInPlace tools/notcurses-core.pc.in \
--replace '$'{prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
substituteInPlace tools/notcurses-ffi.pc.in \
--replace '$'{prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
substituteInPlace tools/notcurses++.pc.in \
--replace '$'{prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
substituteInPlace tools/notcurses.pc.in \
--replace '$'{prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
'';
meta = {
homepage = "https://github.com/dankamongmen/notcurses";
description = "Blingful TUIs and character graphics";
longDescription = ''
Notcurses is a library facilitating complex TUIs on modern terminal
emulators, supporting vivid colors, multimedia, and Unicode to the maximum
degree possible. Things can be done with Notcurses that simply can't be
done with NCURSES.
It is not a source-compatible X/Open Curses implementation, nor a
replacement for NCURSES on existing systems.
'';
license = lib.licenses.asl20;
maintainers = [ ];
inherit (ncurses.meta) platforms;
};
})
|
