1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
{
lib,
stdenvNoCC,
buildGoModule,
fetchFromGitHub,
fetchPnpmDeps,
nodejs,
pnpm_10,
jq,
pnpmConfigHook,
installShellFiles,
versionCheckHook,
nix-update-script,
}:
buildGoModule (finalAttrs: {
pname = "mo-viewer";
version = "1.6.8";
src = fetchFromGitHub {
owner = "k1LoW";
repo = "mo";
tag = "v${finalAttrs.version}";
hash = "sha256-aam8kDxZfNXJyGeyj4ZtDRLcZ9mPVKNHnHfVFFkv/Ro=";
};
frontend = stdenvNoCC.mkDerivation (finalFrontendAttrs: {
pname = "${finalAttrs.pname}-frontend";
inherit (finalAttrs) version src;
pnpmRoot = "internal/frontend";
pnpmDeps = fetchPnpmDeps {
inherit (finalFrontendAttrs) pname version src;
sourceRoot = "${finalFrontendAttrs.src.name}/internal/frontend";
pnpm = pnpm_10;
fetcherVersion = 4;
hash = "sha256-jvTMP8XKUpanM2CQVX/cZr2sqMt6Zgh1JKJhaCeGKt4=";
};
nativeBuildInputs = [
nodejs
pnpm_10
pnpmConfigHook
jq
];
postPatch = ''
jq 'del(.pnpm.executionEnv)' internal/frontend/package.json > internal/frontend/package.json.tmp
mv internal/frontend/package.json.tmp internal/frontend/package.json
'';
buildPhase = ''
runHook preBuild
pnpm -C internal/frontend run build
runHook postBuild
'';
installPhase = ''
runHook preInstall
cp -r internal/static/dist $out
runHook postInstall
'';
});
vendorHash = "sha256-9LXhQUTsk0+UCtXWMFsE4aGG+2MSOyM+U6dlWw+0G+c=";
preBuild = ''
cp -r ${finalAttrs.frontend} internal/static/dist
'';
env.CGO_ENABLED = 0;
ldflags = [
"-s"
"-w"
"-X github.com/k1LoW/mo/version.Revision=v${finalAttrs.version}"
];
nativeBuildInputs = [ installShellFiles ];
postInstall = lib.optionalString (stdenvNoCC.buildPlatform.canExecute stdenvNoCC.hostPlatform) ''
installShellCompletion --cmd 'mo' \
--bash <("$out/bin/mo" completion bash) \
--zsh <("$out/bin/mo" completion zsh) \
--fish <("$out/bin/mo" completion fish)
'';
doCheck = !stdenvNoCC.hostPlatform.isDarwin;
nativeInstallCheckInputs = [ versionCheckHook ];
doInstallCheck = true;
versionCheckProgramArg = "--version";
__structuredAttrs = true;
passthru.updateScript = nix-update-script {
extraArgs = [
"--subpackage"
"frontend"
];
};
meta = {
homepage = "https://github.com/k1LoW/mo";
description = "Markdown viewer that opens .md files in a browser";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ ryota2357 ];
mainProgram = "mo";
};
})
|
