1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
{
lib,
stdenv,
fetchFromGitHub,
fetchYarnDeps,
makeWrapper,
matrix-sdk-crypto-nodejs,
yarnConfigHook,
cargo,
rustPlatform,
rustc,
napi-rs-cli,
pkg-config,
nodejs,
openssl,
nix-update-script,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "matrix-hookshot";
version = "7.4.0";
src = fetchFromGitHub {
owner = "matrix-org";
repo = "matrix-hookshot";
tag = finalAttrs.version;
hash = "sha256-Nsbs3m1sFQaJGqVW8Jk8kSMYXrRnqLBVs6glpuP76ps=";
};
offlineCache = fetchYarnDeps {
inherit (finalAttrs) src;
hash = "sha256-93g8DvTZACDhURoMCaeg5Zqpk1dnbOqscRkSV9lnYCI=";
};
cargoDeps = rustPlatform.fetchCargoVendor {
inherit (finalAttrs) pname version src;
hash = "sha256-FKCzafDeqJs1o24H+Qy/9vRJeG5bEa+/y+yp4T2ADVg=";
};
buildInputs = [ openssl ];
nativeBuildInputs = [
rustPlatform.cargoSetupHook
yarnConfigHook
pkg-config
cargo
rustc
napi-rs-cli
makeWrapper
nodejs
];
preBuild = ''
# We want nixpkgs' version of this instead
rm -rf node_modules/@matrix-org/matrix-sdk-crypto-nodejs
cp -r ${matrix-sdk-crypto-nodejs}/lib/node_modules/@matrix-org/matrix-sdk-crypto-nodejs \
node_modules/@matrix-org/matrix-sdk-crypto-nodejs
chmod -R a+rwx node_modules/@matrix-org/matrix-sdk-crypto-nodejs
'';
buildPhase = ''
runHook preBuild
yarn run build:app:rs --target ${stdenv.hostPlatform.rust.rustcTargetSpec}
yarn run build:app
yarn run build:web
runHook postBuild
'';
installPhase = ''
runHook preInstall
rm -rf ./node_modules
yarn install --production --offline --force --ignore-engines --no-bin-links --frozen-lockfile
# Re-install matrix-sdk-crypto-nodejs
rm -rf node_modules/@matrix-org/matrix-sdk-crypto-nodejs
cp -r ${matrix-sdk-crypto-nodejs}/lib/node_modules/@matrix-org/matrix-sdk-crypto-nodejs \
node_modules/@matrix-org/matrix-sdk-crypto-nodejs
chmod -R a+rwx node_modules/@matrix-org/matrix-sdk-crypto-nodejs
mkdir -p $out/lib/node_modules/matrix-hookshot/
mkdir $out/bin
mv ./lib/* $out/lib/node_modules/matrix-hookshot
mv ./public ./assets ./node_modules ./package.json $out/lib/node_modules/matrix-hookshot
runHook postInstall
'';
postInstall = ''
makeWrapper '${lib.getExe nodejs}' "$out/bin/matrix-hookshot" \
--set NODE_ENV "production" \
--add-flags "$out/lib/node_modules/matrix-hookshot/App/BridgeApp.js"
'';
passthru.updateScript = nix-update-script { };
meta = {
changelog = "https://github.com/matrix-org/matrix-hookshot/blob/${finalAttrs.version}/CHANGELOG.md";
description = "Bridge between Matrix and multiple project management services, such as GitHub, GitLab and JIRA";
homepage = "https://matrix-org.github.io/matrix-hookshot/";
mainProgram = "matrix-hookshot";
maintainers = with lib.maintainers; [ chvp ];
license = lib.licenses.asl20;
platforms = lib.platforms.unix;
};
})
|
