1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
{
lib,
linuxHeaders, # Linux source tree
makeWrapper,
stdenvNoCC,
binutils,
coreutils,
gnugrep,
# decompressors for possible kernel image formats
bzip2,
gzip,
lz4,
lzop,
xz,
zstd,
}:
let
commonDeps = [
binutils
coreutils
gnugrep
gzip
xz
bzip2
lzop
lz4
zstd
];
toWrapScriptLines = scriptName: ''
install -Dm 0755 scripts/${scriptName} $out/bin/${scriptName}
wrapProgram $out/bin/${scriptName} --prefix PATH : ${lib.makeBinPath commonDeps}
'';
in
stdenvNoCC.mkDerivation {
inherit (linuxHeaders) version;
pname = "linux-scripts";
# These scripts will rarely change and are usually not bound to a specific
# version of Linux. So it is okay to just use whatever Linux version comes
# from `linuxHeaders.
src = linuxHeaders.src;
nativeBuildInputs = [ makeWrapper ];
dontConfigure = true;
dontBuild = true;
installPhase = ''
${toWrapScriptLines "extract-ikconfig"}
${toWrapScriptLines "extract-vmlinux"}
'';
meta = {
description = "Standalone scripts from <linux>/scripts";
homepage = "https://www.kernel.org/";
license = lib.licenses.gpl2Only;
maintainers = [ lib.maintainers.phip1611 ];
platforms = lib.platforms.all;
};
}
|
