blob: 65350dc3d7784066c15c861a72366fffa9f81ff5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
{
lib,
stdenv,
fetchFromGitHub,
pkg-config,
autoreconfHook,
curl,
lua,
openssl,
features ? {
urls = false;
# Upstream enables regex by default
regex = true;
# Signature support is broken with openssl 1.1.1: https://github.com/vstakhov/libucl/issues/203
signatures = false;
lua = false;
utils = false;
},
}:
let
featureDeps = {
urls = [ curl ];
signatures = [ openssl ];
lua = [ lua ];
};
in
stdenv.mkDerivation (finalAttrs: {
pname = "libucl";
version = "0.9.4";
src = fetchFromGitHub {
owner = "vstakhov";
repo = "libucl";
rev = finalAttrs.version;
sha256 = "sha256-m6VRtFNKm6+T7pPP2u3avMkVTmye4CM6Z7wjhddVMZE=";
};
nativeBuildInputs = [
pkg-config
autoreconfHook
];
buildInputs = lib.concatLists (
lib.mapAttrsToList (feat: enabled: lib.optionals enabled (featureDeps."${feat}" or [ ])) features
);
enableParallelBuilding = true;
configureFlags = lib.mapAttrsToList (
feat: enabled: lib.strings.enableFeature enabled feat
) features;
meta = {
description = "Universal configuration library parser";
homepage = "https://github.com/vstakhov/libucl";
license = lib.licenses.bsd2;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ jpotier ];
};
})
|
