1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
|
{
lib,
rustPlatform,
stdenv,
fetchFromGitHub,
pkg-config,
wrapGAppsHook4,
bashNonInteractive,
clinfo,
gdk-pixbuf,
gtk4,
libadwaita,
libdisplay-info_0_3,
libdrm,
ocl-icd,
vulkan-loader,
vulkan-tools,
coreutils,
systemdMinimal,
nix-update-script,
nixosTests,
hwdata,
fuse3,
autoAddDriverRunpath,
}:
rustPlatform.buildRustPackage (finalAttrs: {
pname = "lact";
version = "0.10.1";
src = fetchFromGitHub {
owner = "ilya-zlobintsev";
repo = "LACT";
tag = "v${finalAttrs.version}";
hash = "sha256-e5imWq5+LOySCLAQRNkL6cMznAlaXv24vZuzG8giS7s=";
};
cargoHash = "sha256-KKMWUoJ3QJxwdRm65pj5VyhX9WLe5up1OxFYhmRsgZc=";
nativeBuildInputs = [
pkg-config
wrapGAppsHook4
rustPlatform.bindgenHook
autoAddDriverRunpath
];
buildInputs = [
gdk-pixbuf
gtk4
libadwaita
libdisplay-info_0_3
libdrm
ocl-icd
vulkan-loader
vulkan-tools
hwdata
fuse3
];
checkFlags = [
# Requires /dev/fuse, which is unavailable in the Nix build sandbox.
"--skip=tests::apply_settings"
];
# we do this here so that the binary is usable during integration tests
env.RUSTFLAGS = lib.optionalString stdenv.targetPlatform.isElf (
lib.concatStringsSep " " [
"-C link-arg=-Wl,-rpath,${
lib.makeLibraryPath [
vulkan-loader
libdrm
ocl-icd
]
}"
"-C link-arg=-Wl,--add-needed,${vulkan-loader}/lib/libvulkan.so"
"-C link-arg=-Wl,--add-needed,${libdrm}/lib/libdrm.so"
"-C link-arg=-Wl,--add-needed,${ocl-icd}/lib/libOpenCL.so"
]
);
postPatch = ''
substituteInPlace lact-daemon/src/server/handler.rs \
--replace-fail 'run_command("journalctl",' 'run_command("${systemdMinimal}/bin/journalctl",'
substituteInPlace lact-daemon/src/server/handler.rs \
--replace-fail 'Command::new("sh")' 'Command::new("${bashNonInteractive}/bin/bash")'
substituteInPlace lact-daemon/src/server/handler.rs \
--replace-fail 'Command::new("clinfo")' 'Command::new("${clinfo}/bin/clinfo")'
substituteInPlace lact-daemon/src/server/vulkan.rs \
--replace-fail 'Command::new("vulkaninfo")' 'Command::new("${vulkan-tools}/bin/vulkaninfo")'
substituteInPlace lact-daemon/src/server/opencl.rs \
--replace-fail 'Command::new("clinfo")' 'Command::new("${clinfo}/bin/clinfo")'
substituteInPlace lact-daemon/src/socket.rs \
--replace-fail 'run_command("chown"' 'run_command("${coreutils}/bin/chown"'
substituteInPlace res/lactd.service \
--replace-fail ExecStart={lact,$out/bin/lact}
# read() looks for the database in /usr/share so we use read_from_file() instead
substituteInPlace lact-daemon/src/server/handler.rs \
--replace-fail 'Database::read()' 'Database::read_from_file("${hwdata}/share/hwdata/pci.ids")'
'';
postInstall = ''
install -Dm444 res/lactd.service -t $out/lib/systemd/system
install -Dm444 res/io.github.ilya_zlobintsev.LACT.desktop -t $out/share/applications
install -Dm444 res/io.github.ilya_zlobintsev.LACT.svg -t $out/share/icons/hicolor/scalable/apps
'';
preFixup = ''
gappsWrapperArgs+=(
--prefix PATH : "${lib.makeBinPath [ vulkan-tools ]}"
)
'';
postFixup = lib.optionalString stdenv.targetPlatform.isElf ''
patchelf $out/bin/.lact-wrapped \
--add-needed libvulkan.so \
--add-needed libdrm.so \
--add-needed libOpenCL.so \
--add-rpath ${
lib.makeLibraryPath [
vulkan-loader
libdrm
ocl-icd
]
}
'';
passthru.updateScript = nix-update-script { };
passthru.tests = {
inherit (nixosTests) lact;
};
meta = {
description = "Linux GPU Configuration Tool for AMD and NVIDIA";
homepage = "https://github.com/ilya-zlobintsev/LACT";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [
atemu
cything
johnrtitor
];
platforms = lib.platforms.linux;
mainProgram = "lact";
};
})
|
