blob: 7cea354bc6058f8950e7dcb0d5c152081063a8ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
{
lib,
stdenv,
bashNonInteractive,
fetchurl,
}:
# Note: this package is used for bootstrapping fetchurl, and thus
# cannot use fetchpatch! All mutable patches (generated by GitHub or
# cgit) that are needed here should be included directly in Nixpkgs as
# files.
stdenv.mkDerivation (finalAttrs: {
pname = "keyutils";
version = "1.6.3";
src = fetchurl {
url = "https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git/snapshot/keyutils-${finalAttrs.version}.tar.gz";
hash = "sha256-ph1XBhNq5MBb1I+GGGvP29iN2L1RB+Phlckkz8Gzm7Q=";
};
patches = [
./conf-symlink.patch
# This patch solves a duplicate symbol error when building with a clang stdenv
# Before removing this patch, please ensure the package still builds by running eg.
# nix-build -E 'with import ./. {}; pkgs.keyutils.override { stdenv = pkgs.clangStdenv; }'
./0001-Remove-unused-function-after_eq.patch
./pkg-config-static.patch
# Fix build for s390-linux, where size_t is different from ptrdiff_t.
(fetchurl {
url = "https://lore.kernel.org/keyrings/20230301134250.301819-1-hi@alyssa.is/raw";
sha256 = "1cbgwxq28fw5ldh38ngcs7xiqvpnmrw0hw9zzhbhb1hdxkavrc1s";
})
];
buildInputs = [
bashNonInteractive
];
strictDeps = true;
makeFlags = lib.optionals stdenv.hostPlatform.isStatic [ "NO_SOLIB=1" ];
outputs = [
"out"
"lib"
"dev"
"man"
];
postPatch = ''
# https://github.com/archlinux/svntogit-packages/blob/packages/keyutils/trunk/reproducible.patch
substituteInPlace Makefile \
--replace-fail \
'VCPPFLAGS := -DPKGBUILD="\"$(shell date -u +%F)\""' \
'VCPPFLAGS := -DPKGBUILD="\"$(date -ud "@$SOURCE_DATE_EPOCH" +%F)\""'
'';
enableParallelBuilding = true;
env = lib.optionalAttrs (stdenv.hostPlatform.useLLVM) {
NIX_LDFLAGS = "--undefined-version";
};
installFlags = [
"ETCDIR=$(out)/etc"
"BINDIR=$(out)/bin"
"SBINDIR=$(out)/sbin"
"SHAREDIR=$(out)/share/keyutils"
"MANDIR=$(out)/share/man"
"INCLUDEDIR=$(dev)/include"
"LIBDIR=$(lib)/lib"
"USRLIBDIR=$(lib)/lib"
];
__structuredAttrs = true;
meta = {
homepage = "https://people.redhat.com/dhowells/keyutils/";
description = "Tools used to control the Linux kernel key management system";
license = lib.licenses.gpl2Plus;
platforms = lib.platforms.linux;
};
})
|
