blob: 1d5fc8812991a19dfe5c8c61e4f71af6f6be2c2a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
{
lib,
python314,
fetchFromGitLab,
callPackage,
stdenv,
makeWrapper,
nixosTests,
}:
let
python = python314.override {
self = python;
packageOverrides = final: prev: {
django = final.django_6;
django-allauth-async = final.callPackage ./django-allauth-async.nix { };
glitchtip-rust = final.callPackage ./glitchtip-rust.nix { };
};
};
pythonPackages =
with python.pkgs;
[
aiohttp
anonymizeip
arro3-core
arro3-io
boto3
cxxfilt
django
django-allauth-async
django-anymail
django-async-backend
django-cors-headers
django-environ
django-extensions
django-import-export
django-ipware
django-ninja
django-ninja-cursor-pagination
django-organizations
django-postgres-partition
django-prometheus
django-storages
django-vcache
django-vtasks
duckdb
google-cloud-logging
granian
glitchtip-rust
mcp
minidump
opentelemetry-proto
orjson
psycopg
pydantic
sentry-sdk
symbolic
user-agents
uuid6
uwsgi-chunked
whitenoise
]
++ django-allauth-async.optional-dependencies.headless-spec
++ django-allauth-async.optional-dependencies.mfa
++ django-allauth-async.optional-dependencies.socialaccount
++ django-storages.optional-dependencies.boto3
++ django-storages.optional-dependencies.azure
++ django-storages.optional-dependencies.google
++ django-vtasks.optional-dependencies.valkey
++ granian.optional-dependencies.reload
++ granian.optional-dependencies.uvloop
++ mcp.optional-dependencies.cli
++ pydantic.optional-dependencies.email;
frontend = callPackage ./frontend.nix { };
in
stdenv.mkDerivation (finalAttrs: {
pname = "glitchtip";
version = "6.2.6";
pyproject = true;
src = fetchFromGitLab {
owner = "glitchtip";
repo = "glitchtip-backend";
tag = "v${finalAttrs.version}";
hash = "sha256-RGYD6HAFZZTSNJWd8n7/gMy9FkjZno9LO1jGxav5d9M=";
};
postPatch = ''
echo 'import os
ALLAUTH_TRUSTED_CLIENT_IP_HEADER = os.getenv(
"ALLAUTH_TRUSTED_CLIENT_IP_HEADER",
None
)' >> glitchtip/settings.py
'';
propagatedBuildInputs = pythonPackages;
nativeBuildInputs = [
makeWrapper
python
];
buildPhase = ''
runHook preBuild
export DEBUG=0
export DEBUG_TOOLBAR=0
ln -s ${finalAttrs.passthru.frontend} dist
python3 manage.py collectstatic
runHook postBuild
'';
installPhase = ''
runHook preInstall
mkdir -p $out/lib
cp -r . $out/lib/glitchtip
chmod +x $out/lib/glitchtip/manage.py
makeWrapper $out/lib/glitchtip/manage.py $out/bin/glitchtip-manage \
--prefix PYTHONPATH : "$PYTHONPATH"
runHook postInstall
'';
passthru = {
inherit frontend python;
inherit (python.pkgs) django-allauth-async glitchtip-rust;
tests = { inherit (nixosTests) glitchtip; };
updateScript = ./update.sh;
};
meta = {
description = "Open source Sentry API compatible error tracking platform";
homepage = "https://glitchtip.com";
changelog = "https://gitlab.com/glitchtip/glitchtip-backend/-/blob/v${finalAttrs.version}/CHANGELOG";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [
defelo
felbinger
];
mainProgram = "glitchtip-manage";
};
})
|
