1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
{
lib,
stdenv,
fetchFromGitHub,
qt6,
fftw,
itstool,
alsaSupport ? true,
alsa-lib ? null,
jackSupport ? false,
libjack2 ? null,
portaudioSupport ? false,
portaudio ? null,
}:
assert alsaSupport -> alsa-lib != null;
assert jackSupport -> libjack2 != null;
assert portaudioSupport -> portaudio != null;
stdenv.mkDerivation (finalAttrs: {
pname = "fmit";
version = "1.4.6";
src = fetchFromGitHub {
owner = "gillesdegottex";
repo = "fmit";
rev = "v${finalAttrs.version}";
sha256 = "sha256-ydX5Yic0GZkOYyC4EHhf4XPPsdZJDEACssHkLlZrgkY=";
};
nativeBuildInputs = [
qt6.qmake
itstool
qt6.wrapQtAppsHook
];
buildInputs = [
fftw
qt6.qtbase
qt6.qtmultimedia
qt6.qtsvg
]
++ lib.optionals alsaSupport [ alsa-lib ]
++ lib.optionals jackSupport [ libjack2 ]
++ lib.optionals portaudioSupport [ portaudio ];
postPatch = ''
substituteInPlace fmit.pro \
--replace-fail 'FMITVERSIONPRO = $$system(git describe --tags --always)' 'FMITVERSIONPRO = ${finalAttrs.version}' \
--replace-fail 'FMITBRANCHGITPRO = $$system(git rev-parse --abbrev-ref HEAD)' 'FMITBRANCHGITPRO = master'
'';
qmakeFlags = [
"PREFIXSHORTCUT=${placeholder "out"}"
]
++ lib.optionals alsaSupport [
"CONFIG+=acs_alsa"
]
++ lib.optionals jackSupport [
"CONFIG+=acs_jack"
]
++ lib.optionals portaudioSupport [
"CONFIG+=acs_portaudio"
];
meta = {
description = "Free Musical Instrument Tuner";
longDescription = ''
FMIT is a graphical utility for tuning musical instruments, with error
and volume history, and advanced features.
'';
homepage = "http://gillesdegottex.github.io/fmit/";
license = lib.licenses.gpl3Plus;
maintainers = [ ];
platforms = lib.platforms.linux;
};
})
|
