blob: 14a76456dc82eced1df145cb04af03cc09367766 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
{
lib,
buildGoModule,
fetchFromGitHub,
}:
buildGoModule (finalAttrs: {
pname = "fasttrackml";
version = "0.6.0";
src = fetchFromGitHub {
owner = "G-Research";
repo = "fasttrackml";
tag = "v${finalAttrs.version}";
hash = "sha256-Z1Hx8nYaifdlnFqp709+rKVXXXMa6cS3+evTG8ZnwrU=";
};
vendorHash = "sha256-GPnhE85mHg4KyPeB6+fUP4Y1MlpYTgidqawPddg5kyw=";
tags = [
"netgo"
"osusergo"
"sqlite_foreign_keys"
"sqlite_math_functions"
"sqlite_omit_load_extension"
"sqlite_unlock_notify"
];
# skip several tests that need network access
checkFlags =
let
skippedTests = [
# failed to connect to `host=localhost user=postgres database=postgres
"TestImportTestSuite/Test_Ok/sqlite->postgres"
"TestImportTestSuite/Test_Ok/sqlcipher->postgres"
"TestImportTestSuite/Test_Ok/postgres->sqlite"
"TestImportTestSuite/Test_Ok/postgres->sqlcipher"
"TestImportTestSuite/Test_Ok/postgres->postgres"
# test timed out after 10m0s while creating Google Cloud storage bucket
"TestGetArtifactGSTestSuite/Test_Error"
"TestGetArtifactGSTestSuite/Test_Ok"
"TestListArtifactGSTestSuite/Test_Error"
"TestListArtifactGSTestSuite/Test_Ok"
# test failure while trying to create/access S3 bucket
"TestGetArtifactS3TestSuite/Test_Error"
"TestGetArtifactS3TestSuite/Test_Ok"
"TestListArtifactS3TestSuite/Test_Error"
"TestListArtifactS3TestSuite/Test_Ok"
# connect: network is unreachable
"TestArtifactFlowTestSuite/Test_Ok/TestCustomNamespaces"
"TestArtifactFlowTestSuite/Test_Ok/TestExplicitDefaultAndCustomNamespaces"
"TestArtifactFlowTestSuite/Test_Ok/TestImplicitDefaultAndCustomNamespaces"
];
in
[ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
postInstall = ''
# we don't need this binary and it messes with our real python
rm $out/bin/python
'';
meta = {
description = "API for logging parameters and metrics when running machine learning code";
homepage = "https://github.com/G-Research/fasttrackml";
changelog = "https://github.com/G-Research/fasttrackml/releases/tag/v${finalAttrs.version}";
license = lib.licenses.asl20;
maintainers = with lib.maintainers; [ jherland ];
platforms = lib.platforms.unix;
mainProgram = "fasttrackml";
};
})
|
