blob: 69515252202983fda63b99a26fcd9a6958ad22b4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
{
lib,
stdenv,
fetchFromGitHub,
installShellFiles,
buildGoModule,
go,
makeWrapper,
viceroy,
}:
buildGoModule (finalAttrs: {
pname = "fastly";
version = "16.0.0";
src = fetchFromGitHub {
owner = "fastly";
repo = "cli";
tag = "v${finalAttrs.version}";
hash = "sha256-gVKlAbiznaRKwDpiyap4Q3mIhn/ZbnUIFwG3l01ZXQ8=";
# The git commit is part of the `fastly version` original output;
# leave that output the same in nixpkgs. Use the `.git` directory
# to retrieve the commit SHA, and remove the directory afterwards,
# since it is not needed after that.
leaveDotGit = true;
postFetch = ''
cd "$out"
git rev-parse --short HEAD > $out/COMMIT
find "$out" -name .git -print0 | xargs -0 rm -rf
'';
};
subPackages = [
"cmd/fastly"
];
vendorHash = "sha256-U2Ix8ZKGCDrWUJFFXJaL+1EBTbqblWp8slhruHhouIc=";
nativeBuildInputs = [
installShellFiles
makeWrapper
];
# Flags as provided by the build automation of the project:
# https://github.com/fastly/cli/blob/7844f9f54d56f8326962112b5534e5c40e91bf09/.goreleaser.yml#L14-L18
ldflags = [
"-s"
"-w"
"-X github.com/fastly/cli/pkg/revision.AppVersion=v${finalAttrs.version}"
"-X github.com/fastly/cli/pkg/revision.Environment=release"
"-X github.com/fastly/cli/pkg/revision.GoHostOS=${go.GOHOSTOS}"
"-X github.com/fastly/cli/pkg/revision.GoHostArch=${go.GOHOSTARCH}"
];
preBuild = ''
cp ./.fastly/config.toml ./pkg/config/config.toml
ldflags+=" -X github.com/fastly/cli/pkg/revision.GitCommit=$(cat COMMIT)"
'';
preFixup = ''
wrapProgram $out/bin/fastly --prefix PATH : ${lib.makeBinPath [ viceroy ]} \
--set FASTLY_VICEROY_USE_PATH 1
'';
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
export HOME="$(mktemp -d)"
installShellCompletion --cmd fastly \
--bash <($out/bin/fastly --completion-script-bash) \
--zsh <($out/bin/fastly --completion-script-zsh)
'';
meta = {
description = "Command line tool for interacting with the Fastly API";
homepage = "https://github.com/fastly/cli";
changelog = "https://github.com/fastly/cli/blob/v${finalAttrs.version}/CHANGELOG.md";
license = lib.licenses.asl20;
maintainers = with lib.maintainers; [
ereslibre
];
mainProgram = "fastly";
};
})
|
