blob: 2b8f92d52547b4515244fc98b0a2e1f41d822e0f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{
lib,
stdenv,
fetchFromGitHub,
bison,
flex,
pcre2,
libunistring,
ncurses,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "boxes";
version = "2.3.1";
src = fetchFromGitHub {
owner = "ascii-boxes";
repo = "boxes";
rev = "v${finalAttrs.version}";
hash = "sha256-dvhb5KWBQt7g4n0ZTQMcJQljIfavV3g8i+P3PWB6Gwk=";
};
# Building instructions:
# https://boxes.thomasjensen.com/build.html#building-on-linux--unix
nativeBuildInputs = [
bison
flex
];
buildInputs = [
pcre2
libunistring
ncurses
];
dontConfigure = true;
# Makefile references a system wide config file in '/usr/share'. Instead, we
# move it within the store by default.
preBuild = ''
substituteInPlace Makefile \
--replace-fail "GLOBALCONF = /usr/share/boxes" \
"GLOBALCONF=${placeholder "out"}/share/boxes/boxes-config"
'';
makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
installPhase = ''
install -Dm755 -t $out/bin out/boxes
install -Dm644 -t $out/share/boxes boxes-config
install -Dm644 -t $out/share/man/man1 doc/boxes.1
'';
meta = {
description = "Command line program which draws, removes, and repairs ASCII art boxes";
mainProgram = "boxes";
homepage = "https://boxes.thomasjensen.com";
license = lib.licenses.gpl2Plus;
maintainers = with lib.maintainers; [ waiting-for-dev ];
platforms = lib.platforms.unix;
};
})
|
