blob: 9d2b6b397aa03e1f51ee8b35325eafe3f5708dc1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
{
lib,
stdenv,
rustPlatform,
fetchFromGitHub,
autoAddDriverRunpath,
installShellFiles,
writableTmpDirAsHomeHook,
versionCheckHook,
nix-update-script,
}:
rustPlatform.buildRustPackage (finalAttrs: {
pname = "bottom";
version = "0.14.9";
src = fetchFromGitHub {
owner = "ClementTsang";
repo = "bottom";
tag = finalAttrs.version;
hash = "sha256-Dvo3A8NIYp0URgYSJOxLW/zEA7Gnpqu9pk6hvpagFZE=";
};
cargoHash = "sha256-PYbmqiE8G+or1NEtPxnWIXcHnKIBSjQ3FN/Zafb/BTw=";
nativeBuildInputs = [
autoAddDriverRunpath
installShellFiles
];
env = {
BTM_GENERATE = true;
};
postInstall = ''
installManPage target/tmp/bottom/manpage/btm.1
installShellCompletion \
target/tmp/bottom/completion/btm.{bash,fish} \
--zsh target/tmp/bottom/completion/_btm
install -Dm444 desktop/bottom.desktop -t $out/share/applications
install -Dm644 assets/icons/bottom-system-monitor.svg -t $out/share/icons/hicolor/scalable/apps
'';
checkFlags = lib.optionals stdenv.hostPlatform.isDarwin [
# fails to get list of processes due to sandboxing, this functionality works at runtime
"--skip=collection::tests::test_data_collection"
];
doInstallCheck = true;
nativeInstallCheckInputs = [
versionCheckHook
writableTmpDirAsHomeHook
];
versionCheckProgram = "${placeholder "out"}/bin/btm";
passthru = {
updateScript = nix-update-script { };
};
meta = {
changelog = "https://github.com/ClementTsang/bottom/blob/${finalAttrs.version}/CHANGELOG.md";
description = "Cross-platform graphical process/system monitor with a customizable interface";
homepage = "https://github.com/ClementTsang/bottom";
license = lib.licenses.mit;
mainProgram = "btm";
maintainers = with lib.maintainers; [
berbiche
gepbird
];
};
})
|
