blob: 6efd8d221e81147f9bc50f35248ec3927d79df6d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
{
lib,
python3,
fetchFromGitHub,
fetchPypi,
git,
versionCheckHook,
}:
let
python = python3.override {
packageOverrides = self: super: {
cement = super.cement.overridePythonAttrs (old: rec {
pname = "cement";
version = "2.10.14";
src = fetchPypi {
inherit pname version;
hash = "sha256-NC4n21SmYW3RiS7QuzWXoifO4z3C2FVgQm3xf8qQcFg=";
};
patches = [ ];
build-system = old.build-system or [ ] ++ (with python.pkgs; [ setuptools ]);
doCheck = false;
});
};
};
in
python.pkgs.buildPythonApplication (finalAttrs: {
pname = "awsebcli";
version = "3.27.3";
pyproject = true;
doInstallCheck = true;
src = fetchFromGitHub {
owner = "aws";
repo = "aws-elastic-beanstalk-cli";
tag = finalAttrs.version;
hash = "sha256-p7W9HoFND28jcqrMp7cFOzmarxvcA3wFhrOCHyvoj5E=";
};
pythonRelaxDeps = [
"botocore"
"colorama"
"fabric"
"pathspec"
"packaging"
"PyYAML"
"six"
"termcolor"
"urllib3"
"wcwidth"
];
dependencies = with python.pkgs; [
packaging
blessed
botocore
cement
colorama
fabric
pathspec
pyyaml
requests
semantic-version
setuptools
tabulate
termcolor
wcwidth
websocket-client
];
nativeCheckInputs = with python.pkgs; [
git
mock
pytest-socket
pytestCheckHook
versionCheckHook
];
enabledTestPaths = [
"tests/unit"
];
disabledTests = [
# Needs docker installed to run.
"test_local_run"
"test_local_run__with_arguments"
# Needs access to the user's ~/.ssh directory.
"test_generate_and_upload_keypair__exit_code_0"
"test_generate_and_upload_keypair__exit_code_1"
"test_generate_and_upload_keypair__exit_code_is_other_than_1_and_0"
"test_generate_and_upload_keypair__ssh_keygen_not_present"
# AssertionError: Expected 'echo' to be called once. Called 2 times
"test_multiple_modules__one_or_more_of_the_specified_modules_lacks_an_env_yaml"
# fails on hydra only on aarch64-linux
# ebcli.objects.exceptions.CredentialsError: Operation Denied. You appear to have no credentials
"test_aws_eb_profile_environment_variable_found__profile_exists_in_credentials_file"
];
# Propagating dependencies leaks them through $PYTHONPATH which causes issues
# when used in nix-shell.
postFixup = ''
rm $out/nix-support/propagated-build-inputs
'';
meta = {
description = "Command line interface for Elastic Beanstalk";
homepage = "https://aws.amazon.com/elasticbeanstalk/";
changelog = "https://github.com/aws/aws-elastic-beanstalk-cli/blob/${finalAttrs.src.tag}/CHANGES.rst";
license = lib.licenses.asl20;
maintainers = with lib.maintainers; [ kirillrdy ];
mainProgram = "eb";
};
})
|
