blob: b703276b365dca6c407946a03af6278b8098cfae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
{
lib,
stdenv,
fetchFromGitHub,
cmake,
pugixml,
rapidjson,
utf8cpp,
zlib,
nix-update-script,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "assimp";
version = "6.0.5";
outputs = [
"out"
"lib"
"dev"
];
src = fetchFromGitHub {
owner = "assimp";
repo = "assimp";
tag = "v${finalAttrs.version}";
hash = "sha256-QWBi1pl5C76UtPhB6SmFipm9oEdnfhELMT3MqfV6oxg=";
};
# assimp vendors many libraries that we have available in Nixpkgs, and offers no good way of pulling them from non-vendored sources.
# We thus patch the CMake declarations to do so.
# https://github.com/assimp/assimp/issues/5286
# also see:
# https://src.fedoraproject.org/rpms/assimp/blob/e0ca8c040bfd661b6d68551b6dc189ba33ffdac1/f/assimp-unbundle.patch
# https://salsa.debian.org/debian/assimp/-/tree/c60e93150d63590d671d9aab165cf259c71f5df9/debian/patches
patches = [ ./use-system-libraries.patch ];
postPatch = ''
# nix build sandbox does not set /var/tmp up:
# https://github.com/assimp/assimp/issues/6270
substituteInPlace test/unit/UnitTestFileGenerator.h \
--replace-fail 'define TMP_PATH "/var/tmp/"' 'define TMP_PATH "/tmp/"'
'';
nativeBuildInputs = [ cmake ];
buildInputs = [
pugixml
rapidjson
utf8cpp
zlib
];
strictDeps = true;
enableParallelBuilding = true;
cmakeFlags = [
(lib.cmakeBool "ASSIMP_BUILD_ASSIMP_TOOLS" true)
(lib.cmakeBool "ASSIMP_BUILD_TESTS" finalAttrs.finalPackage.doCheck)
(lib.cmakeBool "ASSIMP_WARNINGS_AS_ERRORS" false)
];
# Some matrix tests fail on non-86_64-linux:
# https://github.com/assimp/assimp/issues/6246
# https://github.com/assimp/assimp/issues/6247
# On Darwin, the bundled googletest is not compatible with Clang 21.
# contrib/googletest/googletest/include/gtest/gtest-printers.h:498:35:
# error: implicit conversion from 'char16_t' to 'char32_t' may change the meaning of the represented code unit
# [-Werror,-Wcharacter-conversion]
doCheck = stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isx86_64;
checkPhase = ''
runHook preCheck
bin/unit
runHook postCheck
'';
passthru.updateScript = nix-update-script { };
meta = {
changelog = "https://github.com/assimp/assimp/releases/tag/${finalAttrs.src.tag}";
description = "Library to import various 3D model formats";
mainProgram = "assimp";
homepage = "https://www.assimp.org/";
license = lib.licenses.bsd3;
maintainers = [ ];
platforms = lib.platforms.linux ++ lib.platforms.darwin;
};
})
|
