pkgs/build-support/lib/meson.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

{ stdenv, lib }:

let
  inherit (lib) boolToString optionals;

  # See https://mesonbuild.com/Reference-tables.html#cpu-families
  cpuFamily =
    platform:
    with platform;
    if isAarch32 then
      "arm"
    else if isx86_32 then
      "x86"
    else if isPower64 then
      "ppc64"
    else if isPower then
      "ppc"
    else
      platform.uname.processor;

  crossFile = builtins.toFile "cross-file.conf" ''
    [properties]
    bindgen_clang_arguments = ['-target', '${stdenv.targetPlatform.config}']
    needs_exe_wrapper = ${boolToString (!stdenv.buildPlatform.canExecute stdenv.hostPlatform)}

    [host_machine]
    system = '${stdenv.targetPlatform.parsed.kernel.name}'
    cpu_family = '${cpuFamily stdenv.targetPlatform}'
    cpu = '${stdenv.targetPlatform.parsed.cpu.name}'
    endian = ${if stdenv.targetPlatform.isLittleEndian then "'little'" else "'big'"}

    [binaries]
    llvm-config = 'llvm-config-native'
    rust = ['rustc', '-C', 'target-feature=${
      if stdenv.targetPlatform.isStatic then "+" else "-"
    }crt-static', '--target', '${stdenv.targetPlatform.rust.rustcTargetSpec}']
    # Meson refuses to consider any CMake binary during cross compilation if it's
    # not explicitly specified here, in the cross file.
    # https://github.com/mesonbuild/meson/blob/0ed78cf6fa6d87c0738f67ae43525e661b50a8a2/mesonbuild/cmake/executor.py#L72
    cmake = 'cmake'
  '';

  crossFlags = optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
    "--cross-file=${crossFile}"
  ];

  makeMesonFlags =
    {
      mesonFlags ? [ ],
      ...
    }:
    crossFlags ++ mesonFlags;

in
{
  inherit makeMesonFlags;
}