1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{
lib,
runCommand,
linkFarm,
fetchurl,
fetchgit,
dub,
}:
{
pname,
version,
lock,
}:
let
makeDubDep =
{
pname,
version,
sha256,
}:
{
inherit pname version;
src = fetchurl {
name = "dub-${pname}-${version}.zip";
url = "mirror://dub/${pname}/${version}.zip";
inherit sha256;
};
};
makeGitDep =
{
pname,
version,
repository,
sha256,
}:
{
inherit pname version;
src = fetchgit {
url = repository;
rev = version;
fetchSubmodules = true; # this is the default, but let's be explicit
inherit sha256;
};
};
lockJson = if lib.isPath lock then lib.importJSON lock else lock;
depsRaw = lib.mapAttrsToList (pname: args: { inherit pname; } // args) lockJson.dependencies;
dubDeps = map makeDubDep (lib.filter (args: !(args ? repository)) depsRaw);
gitDeps = map makeGitDep (lib.filter (args: args ? repository) depsRaw);
# a directory with multiple single element registries
# one big directory with all .zip files leads to version parsing errors
# when the name of a package is a prefix of the name of another package
dubRegistryBase = linkFarm "dub-registry-base" (
map (dep: {
name = "${dep.pname}/${dep.pname}-${dep.version}.zip";
path = dep.src;
}) dubDeps
);
in
runCommand "${pname}-${version}-dub-deps"
{
nativeBuildInputs = [ dub ];
}
''
export DUB_HOME="$out/.dub"
mkdir -p "$DUB_HOME"
# register dub dependencies
${lib.concatMapStringsSep "\n" (dep: ''
dub fetch ${dep.pname}@${dep.version} --cache=user --skip-registry=standard --registry=file://${dubRegistryBase}/${dep.pname}
'') dubDeps}
# register git dependencies
${lib.concatMapStringsSep "\n" (dep: ''
mkdir -p "$DUB_HOME/packages/${dep.pname}/${dep.version}"
cp -r --no-preserve=all ${dep.src} "$DUB_HOME/packages/${dep.pname}/${dep.version}/${dep.pname}"
'') gitDeps}
''
|
