1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
{
lib,
fetchFromGitHub,
fetchgit,
}:
let
mkArgs =
{
pname,
version,
variant,
patches ? _: [ ],
rev,
hash,
meta ? { },
}:
{
inherit
pname
version
variant
patches
;
src =
{
"mainline" = (
fetchgit {
url = "https://https.git.savannah.gnu.org/git/emacs.git";
inherit rev hash;
}
);
"macport" = (
fetchFromGitHub {
owner = "jdtsmith";
repo = "emacs-mac";
inherit rev hash;
}
);
}
.${variant};
meta = {
homepage =
{
"mainline" = "https://www.gnu.org/software/emacs/";
"macport" = "https://github.com/jdtsmith/emacs-mac";
}
.${variant};
description =
"Extensible, customizable GNU text editor"
+ lib.optionalString (variant == "macport") " - macport variant";
longDescription = ''
GNU Emacs is an extensible, customizable text editor—and more. At its core
is an interpreter for Emacs Lisp, a dialect of the Lisp programming
language with extensions to support text editing.
The features of GNU Emacs include: content-sensitive editing modes,
including syntax coloring, for a wide variety of file types including
plain text, source code, and HTML; complete built-in documentation,
including a tutorial for new users; full Unicode support for nearly all
human languages and their scripts; highly customizable, using Emacs Lisp
code or a graphical interface; a large number of extensions that add other
functionality, including a project planner, mail and news reader, debugger
interface, calendar, and more. Many of these extensions are distributed
with GNU Emacs; others are available separately.
''
+ lib.optionalString (variant == "macport") ''
This release initially was built from Mitsuharu Yamamoto's patched source code
tailored for macOS. Moved to a fork of the latter starting with emacs v30 as the
original project seems to be currently dormant.
'';
changelog =
{
"mainline" = "https://cgit.git.savannah.gnu.org/cgit/emacs.git/plain/etc/NEWS?h=${rev}";
"macport" = "https://github.com/jdtsmith/emacs-mac/blob/${rev}/NEWS-mac";
}
.${variant};
license = lib.licenses.gpl3Plus;
maintainers =
{
"mainline" = with lib.maintainers; [
AndersonTorres
adisbladis
jwiegley
linj
panchoh
];
"macport" = with lib.maintainers; [
kfiz
];
}
.${variant};
platforms =
{
"mainline" = lib.platforms.all;
"macport" = lib.platforms.darwin;
}
.${variant};
mainProgram = "emacs";
}
// meta;
};
in
{
emacs31 = import ./make-emacs.nix (mkArgs {
pname = "emacs";
version = "31.1";
variant = "mainline";
rev = "emacs-31.1";
hash = "sha256-lFT5Vt49G17t/fRm5yppO5p9ui10I9JNJVaGO1GPZFI=";
});
emacs30-macport = import ./make-emacs.nix (mkArgs {
pname = "emacs-mac";
version = "30.2.50";
variant = "macport";
rev = "emacs-mac-30.2.1";
hash = "sha256-KFgQZBW0QRX0k4k8gkVuGhNTfxArOH1+rwUzsmyEuss=";
patches = fetchpatch: [
(fetchpatch {
# tree-sitter 0.26 compatibility fix, see https://bugs.gentoo.org/970856
url = "https://gitweb.gentoo.org/proj/emacs-patches.git/plain/emacs/30.2/01_all_treesit-0.26.patch?id=d0f47979806d9be5a190fdb4ffa1bde439b2d616";
hash = "sha256-3pWeRxjAhr3ntBR3xDhoDUZDjU6xICU23NUpb/Vl6R4=";
})
(fetchpatch {
# tree-sitter 0.26 compatibility fix, see https://bugs.gentoo.org/971731
url = "https://gitweb.gentoo.org/proj/emacs-patches.git/plain/emacs/30.2/02_all_ts-query-pred.patch?id=86190bf195b3e17108372d8ad89eb57037180dd2";
hash = "sha256-0GPyfKLSaB09a8hamrSf6lx4Qk8Big4AKMOivkN1wEM=";
})
(fetchpatch {
name = "nullify-read-symbol-shorthands-around-risky-intern-calls-80574.patch";
url = "https://cgit.git.savannah.gnu.org/cgit/emacs.git/patch/?id=8466eb44991707d128110bdc549fad14c8e1d61e";
hash = "sha256-SyRCay2MahCJovtzBHA9M1H9hXhtD5IG3ZFSEUwaWlg=";
})
(fetchpatch {
name = "CVE-2026-79992.patch";
url = "https://gitweb.gentoo.org/proj/emacs-patches.git/plain/emacs/30.2/05_all_tramp.patch?id=2a6292f81affedcc468c594c60808e652ae87118";
hash = "sha256-WMjTscIuOXakuTO2H+w/Hd61V61V6ZrLh9WPMd58l+M=";
})
];
});
}
|
