nixos/tests/postgresql/pgjwt.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

{
  runTest,
  genTests,
  ...
}:

let
  makeTestFor =
    package:
    runTest (
      { lib, pkgs, ... }:
      {
        name = "pgjwt-${package.name}";
        meta = with lib.maintainers; {
          maintainers = [
            spinus
          ];
        };

        nodes.master =
          { ... }:
          {
            services.postgresql = {
              inherit package;
              enable = true;
              extensions =
                ps: with ps; [
                  pgjwt
                  pgtap
                ];
            };
          };

        testScript =
          { nodes, ... }:
          let
            sqlSU = "${nodes.master.services.postgresql.superUser}";
            pgProve = "${pkgs.perlPackages.TAPParserSourceHandlerpgTAP}";
            inherit (nodes.master.services.postgresql.package.pkgs) pgjwt;
          in
          ''
            start_all()
            master.wait_for_unit("postgresql.target")
            master.succeed(
                "${pkgs.sudo}/bin/sudo -u ${sqlSU} ${pgProve}/bin/pg_prove -d postgres -v -f ${pgjwt.src}/test.sql"
            )
          '';
      }
    );
in
genTests {
  inherit makeTestFor;
  filter = _: p: !p.pkgs.pgjwt.meta.broken;
}