blob: 00982a6e05bf528d29d14fac47eab386e58364be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
{ pkgs, lib, ... }:
let
token = "1234";
dummyFile = pkgs.writeTextFile {
name = "secrets";
text = "dummy=value";
};
secretFile = pkgs.writeTextFile {
name = "secrets";
text = "token=${token}";
};
portRange = 6003;
in
{
name = "frp";
meta.maintainers = with lib.maintainers; [
zaldnoay
epireyn
];
nodes = {
frps = {
networking = {
useNetworkd = true;
useDHCP = false;
firewall.enable = false;
};
systemd.network.networks."01-eth1" = {
name = "eth1";
networkConfig.Address = "10.0.0.1/24";
};
services.frp.instances.server = {
enable = true;
role = "server";
environmentFiles = [
(builtins.toPath dummyFile)
(builtins.toPath secretFile)
];
settings = {
bindPort = 7000;
vhostHTTPPort = 80;
auth.method = "token";
auth.token = "{{ .Envs.token }}";
};
};
};
frpc = {
networking = {
useNetworkd = true;
useDHCP = false;
};
systemd.network.networks."01-eth1" = {
name = "eth1";
networkConfig.Address = "10.0.0.2/24";
};
services.httpd = {
enable = true;
adminAddr = "admin@example.com";
virtualHosts =
let
testdir = pkgs.writeTextDir "web/index.php" "<?php phpinfo();";
in
{
"test-appication" = {
documentRoot = "${testdir}/web";
locations."/" = {
index = "index.php index.html";
};
};
"test-range" = {
documentRoot = "${testdir}/web";
listen = [
{ port = portRange; }
];
locations."/" = {
index = "index.php index.html";
};
};
};
phpPackage = pkgs.php84;
enablePHP = true;
};
services.frp.instances.client = {
enable = true;
role = "client";
settings = {
serverAddr = "10.0.0.1";
serverPort = 7000;
auth.method = "token";
auth.token = token;
proxies = [
{
name = "web";
type = "http";
localPort = 80;
customDomains = [ "10.0.0.1" ];
}
];
};
extraConfig = ''
{{- range $_, $v := parseNumberRangePair "6000-6006,6007" "6000-6006,6007" }}
[[proxies]]
name = "tcp-{{ $v.First }}"
type = "tcp"
localPort = {{ $v.First }}
remotePort = {{ $v.Second }}
{{- end }}
'';
};
};
};
testScript = ''
start_all()
frps.wait_for_unit("frp-server.service")
frps.wait_for_open_port(80)
frpc.wait_for_unit("frp-client.service")
# Test config written in Nix
response = frpc.succeed("curl -fvvv -s http://127.0.0.1/")
assert "PHP Version ${pkgs.php84.version}" in response, "PHP version not detected"
response = frpc.succeed("curl -fvvv -s http://10.0.0.1/")
assert "PHP Version ${pkgs.php84.version}" in response, "PHP version not detected"
# Test `extraConfig` option with port range
response = frpc.succeed("curl -fvvv -s http://127.0.0.1:${toString portRange}/")
assert "PHP Version ${pkgs.php84.version}" in response, "PHP version not detected"
response = frpc.succeed("curl -fvvv -s http://10.0.0.1:${toString portRange}/")
assert "PHP Version ${pkgs.php84.version}" in response, "PHP version not detected"
'';
}
|
